Увеличить высоту окна вывода скрипта либо добавить вывод в файл

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

Увеличить высоту окна вывода скрипта либо добавить вывод в файл

Есть скрипт, который выводит список пользователей Windows и их последнюю дату входа:

Скрытый текст

Option Explicit
Dim objWMIService, colItems, WshNetwork, strComputer
Dim objUser, objItem, dtmLastLogin, strLogonInfo
Set WshNetwork = CreateObject("Wscript.Network")
strComputer = WshNetwork.ComputerName

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery _
("Select * from Win32_UserAccount Where Domain = '" & strComputer & "'")

For Each objItem in colItems
dtmLastLogin = ""
On Error Resume Next
Set objUser = GetObject("WinNT://" & strComputer _
& "/" & objItem.Name & ",user")
dtmLastLogin = objUser.lastLogin
On Error Goto 0

strLogonInfo = strLogonInfo & vbCrLf & objItem.Name & ": " & dtmLastLogin
Next
MsgBox strLogonInfo, vbOKOnly + vbInformation, "Информация о последнем входе в систему"

Но беда в том, что собирает он максимум 34 пользователя и на 35м вывод в окно обрывается. Может кто поможет увеличить высоту окна (добавить проматывание по высоте), а в идеале заставить его выводить данные в текстовый файл?

Powershell, вывод в файл

Код:

Get-LocalUser |select name,lastlogon > c:\temp\$env:computername-lastlogon.txt

проще заменить строку с msgbox .... на WScript.Echo strLogonInfo и куда угодно: cscript //nologo users.vbs >file.txt

Код:

    strLogonInfo = strLogonInfo & vbCrLf & objItem.Name & ": " & vbTab & dtmLastLogin

Next



''''MsgBox strLogonInfo, vbOKOnly + vbInformation, "Информация о последнем входе в систему"



Dim View: View = "notepad.exe"

With CreateObject("Scripting.FileSystemObject")

    Dim Out: Out = .GetSpecialFolder(2).Path + "\~~~vbs.tmp"

    With .OpenTextFile(Out, 2, True)

        .Write "Информация о последнем входе в систему" & vbCrLf & strLogonInfo

        .Close

    End With

    CreateObject("WScript.Shell").Run """" & View & """ " + Out, 1, True    'False

    If .FileExists(Out) Then .DeleteFile Out, True

End With