запись текста с переменными в файл
Всем привет
столкнулся проблемой, для кого-то может и нет
но смысл такой
Вот часть кода
Скрытый текст
Код:
REM ---------------Изменяем запись cwrsync
@Echo Off
Set cwrfile=c:\Progra~1\cwRsync\cwrsync.cmd
(Echo @ECHO OFF
Echo SETLOCAL
Echo SET "CWRSYNCHOME=C:\PROGRAM FILES\cwRsync"
Echo SET CYGWIN=nontsec
Echo SET CWOLDPATH=%PATH%
Echo SET HOME=%HOMEDRIVE%%HOMEPATH%
Echo SET PATH=%CWRSYNCHOME%\BIN;%PATH%
Echo taskkill.exe /f /im rsync.exe
Echo del /q "C:\PROGRAM FILES\cwRsync\"*.log
Echo rsync -Pav --log-file=MusicUpload.log --bwlimit=80000 --exclude="/TEMP/" --delete-after vasya.ua::music/ /cygdrive/m/music
)>"%cwrfile%"
Так вот
он значения %HOMEDRIVE%%HOMEPATH% а также все с таким знаком не передает в файл cwrsync.cmd в котором я меняю этот текст
Подскажите , мне нужно именно эти значения записать в тот файл , как их правильно передать средствами ".bat" ?? |
Код:
@echo off
set "cwrfile=C:\Progra~1\cwRsync\cwrsync.cmd"
<"%~f0">"%cwrfile%" (for /f "delims=[]" %%a in ('find /n "::(cwrsync.cmd)"^|more +1') do @for /f "delims=" %%b in ('more +%%a^|find /n /v ""') do @set "x=%%b"& cmd/v/c echo[!x:*]^^=!)
exit
::(cwrsync.cmd)
@ECHO OFF
SETLOCAL
SET "CWRSYNCHOME=C:\PROGRAM FILES\cwRsync"
SET "CYGWIN=nontsec"
SET "CWOLDPATH=%PATH%"
SET "HOME=%HOMEDRIVE%%HOMEPATH%"
SET "PATH=%CWRSYNCHOME%\BIN;%PATH%"
taskkill.exe /f /im "rsync.exe"
DEL /q "C:\PROGRAM FILES\cwRsync\*.log"
rsync -Pav --log-file=MusicUpload.log --bwlimit=80000 --exclude="/TEMP/" --delete-after vasya.ua::music/ /cygdrive/m/music
EXIT
|
Цитата:
Цитата magarjoba
он значения %HOMEDRIVE%%HOMEPATH% а также все с таким знаком не передает в файл cwrsync.cmd в котором я меняю этот текст
Подскажите , мне нужно именно эти значения записать в тот файл , как их правильно передать средствами ".bat" ?? »
|
Удваивайте символы %:
Код:
…
>>"%cwrfile%" Echo SET HOME=%%HOMEDRIVE%%%%HOMEPATH%%
…
и т.д. |
Ооооооо, спасибо выручили , я сильно не заморачивался и последний вариант , прост и работает
|
Время: 14:01.
© OSzone.net 2001-
