[решено] чтобы скрипт считывал имя компьютера находил строчку с искомым Computername и выводил

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

чтобы скрипт считывал имя компьютера находил строчку с искомым Computername и выводил

Здравствуйте! Проблема заключается в следующем:
1. Существует программа BGInfo (отображает на рабочем столе информацию)
2. Существует текстовый файл каждая сточка содержит Computername;инвентарныйномерпк
3. Хотелось бы решить проблему чтоб программа BGInfo отображала на рабочем столе инвентарный номер ПК, скрипт считывал имя компьютера находил строчку с искомым Computername и выводил значение на рабочий стол инвентарный номер
Буду очень благодарен! Спасибо.

Цитата:

Цитата DJMix27

2. Существует текстовый файл каждая сточка содержит Computername;инвентарныйномерпк »

Сразу прикладывайте к сообщению образец файла, упакованного в архив.

Попробуйте так:

Скрытый текст

Код:

Option Explicit



Dim strMachineListFile



Dim strComputerName



Dim strLine

Dim strResult





strMachineListFile = "C:\Мои проекты\MachineList.txt"



With CreateObject("Scripting.FileSystemObject")

        If .FileExists(strMachineListFile) Then

                strComputerName = CreateObject("WScript.Network").ComputerName

                

                With .OpenTextFile(strMachineListFile)

                        strResult = "Not found"

                        

                        Do Until .AtEndOfStream

                                strLine = .ReadLine()

                                

                                If StrComp(Trim(Split(strLine, ";")(0)), strComputerName, vbTextCompare) = 0 Then

                                        strResult = Split(strLine, ";")(1)

                                        

                                        Exit Do

                                End If

                        Loop

                        

                        .Close

                        

                        Echo strResult

                End With

                

        Else

                Echo "Can't find machine list file [" & strMachineListFile & "]."

        End If

End With

Спасибо огромное! Все работает как нужно!