Вопрос как зделать чтобы, (.bat) файл ждал включения программы
Вопрос как сделать чтобы, (.bat) файл ждал включения программы, на-пример: "Skype.exe" и увидев ее сразу отключал, и потом сам отключился.
|
Код:
@echo off
set "p=Skype.exe"
cmd/c for /l %%i in () do @tasklist /fi "imagename eq %p%"^| findstr/v :^&^& (taskkill /f /im "%p%"^& exit/b)
|
ufooo, Если skype запускается батником, то можно отловить его запуск из другого батника. Например:
Код:
:: Батник для запуска (блокнот в качестве примера)
@echo off
start notepad
waitfor /si test
Код:
:: Батник, который отлавливает сигнал "test", запускается первым
@echo off
waitfor test
taskkill /im notepad.exe
Иначе, как у Georgio, в бесконечном цикле проверять наличие процесса.
|
Foreigner!
Не-плохая идея. Нет больше 100% нагрузки на: "Cpu".
|
Хех, оказывается, отелились насилу к Vista/Windows 7 озаботиться хоть каким-то взаимодействием ;).
Цитата:
Цитата ufooo
Не-плохая идея. Нет больше 100% нагрузки на: "Cpu". »
|
Добавьте в код коллеги Georgio внутрь цикла таймаут (например, «>nul timeout /t 1 /nobreak») — и «100% нагрузки» не будет.
|
Цитата:
Цитата Iska
Добавьте в код коллеги Georgio внутрь цикла таймаут »
|
Мне с добавлением, (>nul timeout /t 1 /nobreak) будет трудновато. |
Код:
@echo off
set "p=Skype.exe"
cmd/c for /l %%i in () do @tasklist /fi "imagename eq %p%"^| findstr/v :^&^& (taskkill /f /im "%p%"^& exit/b)^& ^>nul timeout /t 1 /nobreak
|
| turbolover |
24-04-2016 21:30 2629297 |
Спрячем этот процесс от любопытных глаз!
Код:
@if "%1" neq "*" (
mshta vbscript:Execute("CreateObject(""WScript.Shell"").Run """"""%~f0"""" *"",0,False:Close()"^)
exit/b
)
set "p=Skype.exe"
cmd/c for /l %%i in () do @tasklist /fi "imagename eq %p%"^| findstr/v :^&^& (taskkill /f /im "%p%"^& exit/b)^& ^>nul timeout /t 1 /nobreak
|
turbolover
Теперь совсем хорошо, консоль спрятана и неболтается на рабочем столе.
|
| Sasssssssha |
10-05-2016 11:58 2633464 |
Вот, то что надо только не могли бы кто-нибудь подредактировать чтобы бат ждал открытия проги, после того как увидел открытую бат продолжал свою работу далее
|
Время: 11:37.
© OSzone.net 2001-
