[решено] Копировать файл с присвоением имени из списка в папку с текущей датой

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

Копировать файл с присвоением имени из списка в папку с текущей датой

эхх тяжело быть дураком, ребята помогите с батноком!

1. создать папку с именем даты её создания (05.03.2016)
2. копировать в только что созданную папку файл лежащий рядом с батником (sources.png)
3. присвоить ему имя из txt файла (name_list.txt)
4. этот же файл должен копироваться с присвоенными именами до конца списка.

Самостоятельные попытки разобраться не приводят к результату, я далёк от этого.
Как создать папку рядом с батником нашел

Код:

set sFolderName=%date%

md "%sFolderName::=-%"

Как в неё копировать файл и переименовать из списка - не понимаю.

Код:

COPY "%~dp0*sources.png*" "куда??"

Присвоение имени из файла не нашел вообще.

Цитата:

Цитата blither

эхх тяжело быть дураком, ребята помогите с батноком! »

«Всёвыврёте» :). Совсем не тяжело.

Код:

@echo off

setlocal enableextensions enabledelayedexpansion



set sSourceFile=%~dp0sources.png

set sNameListFile=name_list.txt

set sDestFolder=%date:~6,4%%date:~3,2%%date:~0,2%



if exist "%sSourceFile%" (

        if exist "%sNameListFile%" (

                2>nul md "%sDestFolder%"

                for /f "usebackq delims=" %%i in ("%sNameListFile%") do (

                        echo [%%~i]

                        >nul copy /y "%sSourceFile%" "%sDestFolder%\%%~i"

                )

        ) else (

                echo Can't find name list file [%sNameListFile%].

                exit /b 2

        )

) else (

        echo Can't find source file [%sSourceFile%].

        exit /b 1

)



endlocal

exit /b 0

Iska, шикарно! Один момент, что нужно изменить чтоб сохранялось расширение копируемого файла?
Большое спасибо!

Iska, нашел

Код:

"%sDestFolder%\%%~i.*"

Спасибо!