Как подключить через прокси браузер Google chrome или mozilla с помощью bat?

Выставить в Google chrome или mozilla опцию прибл. ~ "Получать системные настройки прокси (обычно так по-умолчанию)".
Они будут подтягиваться от IE.

Смена настроек в IE такова:

Код:

::Конфигуратор системной прокси для IE

@echo off

::Включить прокси (y/n)

set EnableProxy=y

::Использовать прокси для локальных адресов (y/n)

set ForLocal=n

set Address=192.168.0.100

set Port=3128

::Очистить настройки "Адрес/порт" прокси (y/n)

set ClearProxy=n

 

set hive=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings

if %EnableProxy%==y (

    reg.exe add "%hive%" /v ProxyEnable /t REG_DWORD /d 0x1 /f

  ) else (

    reg.exe add "%hive%" /v ProxyEnable /t REG_DWORD /d 0x00000000 /f 

)

if %ForLocal%==n (

    reg.exe delete "%hive%" /v ProxyOverride /f

  ) else (

    reg.exe add "%hive%" /v ProxyOverride /t REG_SZ /d ^<local^> /f

)

if %ClearProxy%==n (

    reg.exe add "%hive%" /v ProxyServer /t REG_SZ /d %Address%:%Port% /f

  ) else (

    reg.exe delete "%hive%" /v ProxyServer /f 

)

Или вот такие самостоятельные коды (бекап настроек, удаление, восстановление из созданного ini):
1) Бэкап проксянки:

Код:

@echo off

setlocal enabledelayedexpansion

set cfg=proxy.ini

if exist %cfg% del /f /q %cfg%

for %%N in (ProxyServer ProxyOverride ProxyEnable) do (

  set /a nkey+=1

  if !nkey!==3 (set ktype=REG_DWORD) else set ktype=REG_SZ

  For /F "UseBackQ Tokens=2*" %%A In (`Reg.exe Query "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"^|Find /I "%%N"`) do set var=%%B

  echo %%N=!ktype!=!var!>>%cfg%

  set var=

)

В создаваемом файле Proxy.ini должно получится нечто вроде этого:

Код:

ProxyServer=REG_SZ=192.168.0.100:3128

ProxyOverride=REG_SZ=<local>

ProxyEnable=REG_DWORD=0x1

2) Удалить настройки прокси и отключить ее использование:

Код:

@echo off

set hive=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings

reg.exe add "%hive%" /v ProxyEnable /t REG_DWORD /d 0x00000000 /f

reg.exe delete "%hive%" /v ProxyOverride /f

reg.exe delete "%hive%" /v ProxyServer /f

3) Восстановление настроек прокси из бэкапа:

Код:

@echo off

set cfg=proxy.ini

for /f "tokens=1,2,3 delims==" %%A in (%cfg%) do (

  if "%%C" neq "" reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v %%A /t %%B /d %%C /f  

)

Настройки применяются сразу, но чтобы их подхватить у браузера IE, следует перезапустить использующие их сторонние приложения.
На всякий случай: параметры Proxy для IE вручную задаются через L Alt, "Сервис", "Свойства обозревателя", вкладка "Подключения", кнопка "Настройка сети".