 |
|
Создание ярлыка
Как сделать так чтобы ярлык который создается с помощью этого скрипта не зависил от наименования профиля пользователя. То есть, вместо "Администратор" написать переменную "%userprofile%", а то у меня ярлык создается когда конкретно указываю пользователя, а когда "%userprofile%" пишет ошибку. Помогите решить этот вопрос спасибо!
Код:
Set WshShell = WScript.CreateObject("WScript.Shell")
' Создание ярлыка: "
' Set oShellLink = WshShell.CreateShortcut("%userprofile%\Рабочий стол\Поиск в Google.lnk")
Set oShellLink = WshShell.CreateShortcut("c:\Documents and Settings\Администратор\Рабочий стол\Поиск в Google.lnk")
' Целевой путь к файлу для которого создаётся ярлык:
oShellLink.TargetPath = "http://google.com/"
' Стиль открытия окна:
' 1 - Обычный размер окна; 3 - Развёрнутое на весь экран; 7 - Свёрнутое в значoк
oShellLink.WindowStyle = 1
' Клавиши быстрого вызова:
oShellLink.Hotkey = "CTRL+SHIFT+G"
' Путь к файлу который содержит иконку для ярлыка:
oShellLink.IconLocation = "%SystemRoot%\system32\SHELL32.dll, 220"
' Комментарий:
oShellLink.Description = "Запустить поисковик"
oShellLink.Save
П.С. Может это связано из кодировкой(крякозябликами) в командной строке?
 |
Код:
Option Explicit
With WScript.CreateObject("WScript.Shell").CreateShortcut(WScript.CreateObject("Shell.Application").NameSpace("shell:desktop").self.Path & "\Поиск в Google.lnk")
.TargetPath = "http://google.com/"
.WindowStyle = 1
.Hotkey = "CTRL+SHIFT+G"
.IconLocation = "SHELL32.dll,220"
.Description = "Запустить поисковик"
.Save
End With
WScript.Quit 0
Цитата:
Цитата yaoleg2
П.С. Может это связано из кодировкой(крякозябликами) в командной строке? »
|
Нет, не связано. Выберете TrueType шрифт для окна консоли. |
Большое спасибо!!! :yahoo:
|
Извините, а как создать ярлык, но чтобы веб-страница окрывалась в новом окне браузера, а не в открытом?
Спасибо!
|
Цитата:
Цитата yaoleg2
а как создать ярлык, но чтобы веб-страница окрывалась в новом окне браузера, а не в открытом? »
|
Зависит от браузера. У Вас какой? |
Пробуйте так:
Код:
Option Explicit
With WScript.CreateObject("WScript.Shell").CreateShortcut(WScript.CreateObject("Shell.Application").NameSpace("shell:desktop").self.Path & "\Поиск в Google.lnk")
.TargetPath = "%ProgramFiles%\Internet Explorer\iexplore.exe"
.Arguments = "http://google.com/"
.WindowStyle = 1
.Hotkey = "CTRL+SHIFT+G"
.IconLocation = "SHELL32.dll,220"
.Description = "Запустить поисковик"
.Save
End With
WScript.Quit 0
|
Время: 21:08.
© OSzone.net 2001-