VBS - Спрятанный ввод
Нужна функция вроде InputBox и при вводе отображались звездочки
Но отправлялась именно введенная информация а не звездочки
(Нужно для формы ввода пароля)
|
Ragnazar, можете попробовать так:
читать дальше »
Код:
Option Explicit
Const READYSTATE_COMPLETE = 4
Dim objIE
Dim objWindow
Dim boolDone
Dim strPassword
Set objIE = WScript.CreateObject("InternetExplorer.Application", "IE_")
With objIE
.Navigate "about:blank"
Do
WScript.Sleep 100
Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
.AddressBar = False
.MenuBar = False
.StatusBar = False
.ToolBar = False
With .Document
.write "<!DOCTYPE HTML PUBLIC ""-//W3C//DTD HTML 4.0 Strict//EN"">" & vbCrLf & _
"<html>" & vbCrLf & _
" <head>" & vbCrLf & _
" <meta http-equiv='Content-Type' content='text/html; charset=windows-1251'>" & vbCrLf & _
" <meta http-equiv='Content-Language' content='ru'>" & vbCrLf & _
" <title>Input password</title>" & vbCrLf & _
" <style>" & vbCrLf & _
" body {" & vbCrLf & _
" margin: 1em 1em 1em 1em;" & vbCrLf & _
" color: MidnightBlue;" & vbCrLf & _
" background-color: LightSteelBlue" & vbCrLf & _
" }" & vbCrLf & _
" </style>" & vbCrLf & _
" </head>" & vbCrLf & _
" <body>" & vbCrLf & _
" <label for='sPassword' accesskey='P'>Enter <u>p</u>assword:</label>" & vbCrLf & _
" <input type='password' name='sPassword' id='sPassword' size='50'>" & vbCrLf & _
" <input type='button' value='OK' name='OK'>" & vbCrLf & _
" <input type='button' value='Отмена' name='Cancel'>" & vbCrLf & _
" </body>" & vbCrLf & _
"</html>"
.getElementsByName("OK").item(0).onclick = GetRef("IEButtonClick")
.getElementsByName("Cancel").item(0).onclick = GetRef("IEButtonClick")
With .getElementByID("sPassword")
.onKeyPress = GetRef("IEOnKeyPress")
.focus
End With
Set objWindow = .parentWindow
With .Body
objWindow.resizeTo .scrollWidth + 25, .scrollHeight + 32
objWindow.moveTo (objWindow.screen.availWidth - .offsetWidth) \ 2, (objWindow.screen.availHeight - .offsetHeight) \ 2
End With
Set objWindow = Nothing
'.getElementByID("sPassword").focus
End With
.Visible = True
boolDone = False
strPassword = Empty
Do
WScript.Sleep 100
Loop Until boolDone
On Error Resume Next
.Quit
On Error Goto 0
End With
Set objIE = Nothing
If Not IsEmpty(strPassword) Then
WScript.Echo "Password is [" & strPassword & "]"
Else
WScript.Echo "Password is not entered"
End If
WScript.Quit 0
'=============================================================================
'=============================================================================
Sub IE_OnQuit
boolDone = True
End Sub
'=============================================================================
'=============================================================================
Sub IEButtonClick
Select Case Me.Name
Case "OK"
strPassword = objIE.Document.getElementByID("sPassword").Value
boolDone = True
Case "Cancel"
boolDone = True
Case Else
' Nothing to do
End Select
End Sub
'=============================================================================
'=============================================================================
Sub IEOnKeyPress
Select Case Me.ownerDocument.parentWindow.event.keyCode
Case 13
strPassword = Me.Value
boolDone = True
Case 27
boolDone = True
Case Else
' Nothing to do
End Select
End Sub
'=============================================================================
|
Спасибо!
Только вот при пустом пароле (ничего не вводя) выдает Password is []
Тоесть else почему-то не работает
Можно-ли как-то изменить активное окно? А то папка со скриптом остается активным
|
Цитата:
Цитата Ragnazar
Только вот при пустом пароле (ничего не вводя) выдает Password is [] »
|
Ragnazar, всё верно. Ничего не ввели и нажали «OK»/«Enter» — пароль пустой. Нажали «Отмена»/«Esc» или просто закрыли диалог — то есть, отказались от ввода пароля — это другое. Попробуйте.
Цитата:
Цитата Ragnazar
Можно-ли как-то изменить активное окно? А то папка со скриптом остается активным »
|
Вопрос не понятен. Поясните. |
Когда создается некое окно (от боксов до ie) то они как-то на заднем плане.
Что-бы они стали активными на них надо нажать но можно-ли автоматически это сделать?
|
Ragnazar, понятней не стало. Что за «боксы»?
|
InputBox NsgBox Wscript.Echo
Когда на alt+Tab нажимаешь то меняется активное окно
|
Ясно. «Боксы» — это окна диалогов.
Теперь переведите всю фразу на русский язык:
Цитата:
Цитата Ragnazar
Когда создается некое окно (от боксов до ie) то они как-то на заднем плане. »
|
|
Когда создается диалоговое окно то что-бы оно было поверх всех окон мне нужно на него нажать
Или выбрать через Alt+Tab
Или нажать на него на панели Пуск (В нижней части где все включеные окна)
|
Цитата:
Цитата Ragnazar
Когда создается диалоговое окно »
|
Речь идёт всё ещё про это окно, создаваемое скриптом:
? |
Да и про него тоже
 |
У меня такого не происходит.
Запишите короткое видео, демонстрирующее данное поведение с данным скриптом.
|
Ragnazar, насколько я понимаю, у Вас проблема в том окне, откуда Вы запускаете скрипты. Что это за окно? Оно не похоже на окно Проводника.
|
Да. Это Explorer++ (Проводник со вкладками)
Но такая проблема из видео только с этим скриптом
|
Ragnazar, скажите, наблюдается ли у Вас та же проблема при использовании обычного Проводника?
|
Ragnazar, сожалею, у меня подобного не происходит.
|
Время: 18:57.
© OSzone.net 2001-
