Вытянуть ссылку с документа MS Word в IE - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- AutoIt (http://forum.oszone.net/forumdisplay.php?f=103)

- - Вытянуть ссылку с документа MS Word в IE (http://forum.oszone.net/showthread.php?t=205125)

Вытянуть ссылку с документа MS Word в IE

Здравствуйте!

Проблема в следующем - у меня есть много ссылок типа http://www.rts-tender.ru/DFile.ashx?...1-04152506e117 по ним в Internet Explorer открывается документ MS Word в котором нужно вытянуть ссылку организации, то есть http://www.rts-tender.ru/Participant...w.aspx?id=7982

Проблема в том что я не могу корректно (без изврата) вытянуть нужную мне ссылку. Подскажите как это можно сделать.

sniper_super, примерно так:

Код:

#Include <File.au3>



AutoItSetOption("MustDeclareVars", 1)



Local $sUrl          = "http://www.oszone.net/go.php?url=http://www.rts-tender.ru/DFile.ashx?guid=87864c7c-1741-4e0b-9a81-04152506e117"

Local $sTempFileName = _TempFile()





If InetGet($sUrl, $sTempFileName, 1) = 0 Then

        ConsoleWriteError("Can't download link [" & $sUrl & "] into local file [" & $sTempFileName & "]" & @CRLF)

        Exit(1)

EndIf



Local $oWord     = ObjCreate("Word.Application")

Local $oDocument = $oWord.Documents.Open($sTempFileName, False, True)

Local $oTable    = $oDocument.Tables.Item(3)



Local $oHyperlink

Local $i



For $i = 2 To $oTable.Rows.Count

        For $oHyperlink In $oTable.Cell($i, 5).Range.Hyperlinks

                ConsoleWrite($oHyperlink.TextToDisplay & ":[" & $oHyperlink.Address & "]" & @CRLF)

        Next

Next



$oTable    = 0

$oDocument.Close()

$oDocument = 0

$oWord.Quit()

$oWord     = 0



FileDelete($sTempFileName)



Exit(0)

Цитата:

Код:

ООО Дельрус-Новосибирск:[http://www.rts-tender.ru/Participant/ParticipantView.aspx?id=7982]

sniper_super,
*click*

Iska, СПАСИБО! То что нужно