[решено] VBS-скипт и метка тома CD/DVD - Компьютерный форум OSzone.net

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- Скриптовые языки администрирования Windows (http://forum.oszone.net/forumdisplay.php?f=102)

- - [решено] VBS-скипт и метка тома CD/DVD (http://forum.oszone.net/showthread.php?t=196517)

VBS-скипт и метка тома CD/DVD

прошу помощи в решении задачи:

написать VBS-скрипт, который при запуске сканирует все имеющиеся CD/DVD-приводы на наличие диска с меткой тома "MY_DISK_2011"

1) если все CD/DVD-приводы пусты выводит сообщение "Вставьте диск в CD/DVD-привод и нажмите ОК",

2) если в CD/DVD-приводах вставлены диски имеющие другую метку тома (отличную от "MY_DISK_2011"), то выводит сообщение "Вставьте MY_DISK_2011 и нажмите ОК",

3) при нажатии ОК скрипт проверяет вставлен ли диск (до тех пор пока диск не появится).

4) в случае обнаружения диска с меткой "MY_DISK_2011" , запускает файл SETUP.EXE в корне диска.

Где-то примерно так:

Код:

Option Explicit



ScanCDROM

WScript.Quit 0



Sub ScanCDROM()

  Dim CheckDisk

  Dim fso

  Dim iDrive

  Dim WSShell

  Dim RetVal

    CheckDisk = False

    Set fso = CreateObject("Scripting.FileSystemObject")

    For Each iDrive in fso.Drives

      If iDrive.DriveType = 4 Then      

        If iDrive.IsReady Then

          CheckDisk = True

          If iDrive.VolumeName = "MY_DISK_2011" Then

            Set WSShell = CreateObject("WScript.Shell")

            WSShell.Run iDrive.Path & "\SETUP.EXE"

            Set WSShell = Nothing

            Set fso = Nothing

            Exit Sub

          End If    

        End If     

      End If

    Next

    If CheckDisk Then 

      RetVal = MsgBox("Вставьте MY_DISK_2011 и нажмите ОК", 65, "Сканирование CDROM")  

    Else

      RetVal = MsgBox("Вставьте диск в CD/DVD-привод и нажмите ОК", 65, "Сканирование CDROM")

    End If

    If Retval = 1 Then ScanCDROM

    Set fso = Nothing

End Sub