[решено] Запуск определенной программы через n времени???

Компьютерный форум OSzone.net (http://forum.oszone.net/index.php)

- AutoIt (http://forum.oszone.net/forumdisplay.php?f=103)

Запуск определенной программы через n времени???

Нужен скрипт, который постоянно сидел бы в системном трее и через каждые 2 недели запускал программу (или каждый месяц 10 и 20 числа). И если комп был в это время выключен то программа должна запуститься при его включении. Заранее спасибо!

Цитата:

Цитата Anarasius

Нужен скрипт, который постоянно сидел бы в системном трее и через каждые 2 недели запускал программу (или каждый месяц 10 и 20 числа) »

Вот так примерно:

Код:

#RequireAdmin



;Добавляем программу в автозапуск

If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then _

    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')



;Указываем программу на запуск

$sApp = "notepad.exe"



While 1

    If @MDAY = 10 Then

        Run($sApp)



        While @MDAY = 10

            Sleep(60000)

        WEnd

    EndIf



    Sleep(1000)

WEnd

Все отлично, но он у меня бесконечно запускает программу через каждую сек

Цитата:

Цитата Anarasius

он у меня бесконечно запускает программу через каждую сек »

Если 10-ое число? В поставленной задачи ничего не сказано по поводу одноразового запуска :)

Поправил свой пост.

Всеравно, я ставлю сегодняшнее число и запускаю скрипт он начинает бесконечно открывать блокнот, попробуйте сами!

Пробовал без добавления в автозапуск

А так:

Код:

#RequireAdmin



;Добавляем программу в автозапуск

If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then _

    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')



;Указываем программу на запуск

$sApp = "notepad.exe"



;Указываем число запуска

$nDay = 16



While 1

    If @MDAY = $nDay Then

        Run($sApp)



        While @MDAY = $nDay

            Sleep(60000)

        WEnd

    EndIf



    Sleep(1000)

WEnd

Я бы добавил последнюю дату запуска в реестр или в ini-файл:

Цитата:

Цитата Anarasius

И если комп был в это время выключен то программа должна запуститься при его включении. Заранее спасибо! »

Все самое главное забыли :tongue:

Вот ... извиняйте если что забыл :) (Оставлю ка я себе програмку пригодится)
Количество "чисел" для запуска вроде как неограничено, можно хоть 20 раз за месяц...

Код:

#NoTrayIcon

#include <File.au3>



If WinExists(@ScriptName) Then _Exit()

AutoItWinSetTitle(@ScriptName)



Opt("TrayMenuMode",1)

TraySetClick(8)

TraySetIcon("Shell32.dll", 25)

TraySetToolTip ("Планировщик запуска")



HotKeySet("!p", "_Exit") ; Alt + P выход



Global $IniFile = @ScriptDir & "/Data_" & @ScriptName & ".ini"

Global $iMDAY

Global $NumberMonth[3]

       $NumberMonth[0] = 10 ; Нужные числа для запуска

       $NumberMonth[1] = 20

       $NumberMonth[2] = 28

Global Const $iNumberNull = $NumberMonth[0]



If Not FileExists($IniFile) Then _FileCreate($IniFile)



If @Compiled = 1 Then

    If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then

        $iMsgBox = MsgBox(266532,"","Поместить программу в автозагрузку ?")

        If $iMsgBox = 6 Then RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')

    EndIf

EndIf



$nAbout  = TrayCreateItem("Тут цопирайты (С) :)")

TrayCreateItem("")

$nExit  = TrayCreateItem("Выйти из планировщика задачь")

TraySetState()



$iIniRead = IniRead($IniFile, "Data", "Run", 0)

If $iIniRead = 0 Then IniWrite($IniFile, "Data", "Run", "<" & @MDAY & "> <" & @MON & ">")



$aiArray = StringRegExp($iIniRead, '<(.*?)>', 3)

If Not (@error) Then

    If @MDAY > $aiArray[0] Then $NumberMonth[0] = @MDAY

    If @MON <>  $aiArray[1] Then $NumberMonth[0] = @MDAY

EndIf



While 1

    Switch TrayGetMsg()

        Case $nExit

            _Exit()

        Case $nAbout

            MsgBox(270400,"About", "Цопирайтинг (С) 2009", 5)



        Case Else

            If @MDAY <> $iMDAY Then

                For $iI = 0 To UBound($NumberMonth) - 1

                    If @MDAY = $NumberMonth[$iI] Then

                        TraySetIcon("Shell32.dll", 246)

                        TrayTip("Запускаем ...", "Планироващик задачь", 0, 1)

                        RunWait("notepad") ; Программа для запуска

                        IniWrite($IniFile, "Data", "Run", "<" & @MDAY & "> <" & @MON & ">")

                        $NumberMonth[0] = $iNumberNull

                        TraySetIcon("Shell32.dll", 25)

                        ExitLoop

                    EndIf

                Next

            EndIf

            $iMDAY = @MDAY

    EndSwitch

WEnd



Func _Exit()

    Exit

EndFunc

Цитата:

Цитата FlatX007

Все самое главное забыли »

И что это? добавление в автозапуск?

Цитата:

Цитата FlatX007

Цитата:

Цитата Anarasius

И если комп был в это время выключен то программа должна запуститься при его включении. Заранее спасибо!

Все самое главное забыли »

Я так понял... если запуск на запланированное число был пропущен(например если компьютер в этот день ни разу не включали), то нужно запустить программу как только это станет возможным, т.е. уже не зависимо от назначенного числа.

P.S. ИМХО, это уже почти "Планировщик задач" получается. :)

И ребят в скрипте где то ошибка, если мы перезагружаем комп, то скрипт после этого пишет что тип запуск программы был а на самом деле Run он не выполнил. (это если вместо notepad прописать программу какуюнибуть (С/progam files/......))

Цитата:

Цитата Anarasius

(это если вместо notepad прописать программу какуюнибуть (С/progam files/......)) »

Прямой путь для запуска не стоит использовать.
Папка "программ файл" - (Вся система) не всегда находится на диске С ... у меня вот она на диске D
Для этого используют макро : @ProgramFilesDir

Код:

RunWait(@ProgramFilesDir & '\Windows Media Player\wmplayer.exe')

Run(@ProgramFilesDir & '\Windows Media Player\wmplayer.exe')

хмм, программа при наступлении нужной даты запускается целый день т.е. если у меня настало 10 число программа запустилась, перезагружаю опять запустилась, как это убрать т.е.что бы программа запускалась только один раз при наступлении даты.

В шапке темы об этом не слова!

Цитата:

Цитата Anarasius

как это убрать т.е.что бы программа запускалась только один раз при наступлении даты. »

Вот именно поэтому задачу изначально нужно поставить так, чтобы потом небыло вопросов и переделок:

Код:

#NoTrayIcon

#include <Misc.au3>

;



_Singleton(@ScriptName)



;Задаём опции трея (меню пользователя)

Opt("TrayMenuMode", 1)



;Создаём пункты в значке трея

Global $nAbout_TrayItem = TrayCreateItem("About...")

TrayCreateItem("")

Global $nExit_TrayItem = TrayCreateItem("Выйти из планировщика задач    (Ctrl+Shift+E)")



;Задаём состояние трея

TraySetToolTip("Планировщик запуска")

TraySetIcon("Shell32.dll", 25)

TraySetClick(8)

TraySetState()



;Задаём горячую клавишу для выхода

HotKeySet("^+e", "_Exit") ; Ctrl + Shift + E выход



;Указываем файл конфигурации

Global $sConfig_File = StringTrimRight(@ScriptFullPath, 3) & "ini"



;Указываем программу(ы) для запуска

Global $aRun_Apps = StringSplit("notepad.exe|calc.exe", "|")



;Указываем числа для запуска программ(ы)

Global $aRun_Days = StringSplit("10,20,30", ",")



;Определяем последнюю дату запуска

Global $sLast_Run_Day = IniRead($sConfig_File, "Main", "Last Run Day", -1)



;Добавляем программу в автозапуск

If @Compiled = 1 Then

    If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then

        $iAsk = MsgBox(266532, "", "Поместить программу в автозагрузку?")



        If $iAsk = 6 Then _

            RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')

    EndIf

EndIf



;Запускаем функцию _Check_Run_Proc() каждые 5 секунд

AdlibEnable("_Check_Run_Proc", 5000)

Call("_Check_Run_Proc")



;Главный цикл

While 1

    Switch TrayGetMsg()

        Case $nExit_TrayItem

            _Exit()

        Case $nAbout_TrayItem

            MsgBox(270400, "About", "Copyright (С) 2009", 5)

    EndSwitch

WEnd



Func _Check_Run_Proc()

    If @MDAY = $sLast_Run_Day Then Return



    For $i = 1 To $aRun_Days[0]

        If @MDAY = $aRun_Days[$i] Then

            ;Запоминаем последний день запуска

            $sLast_Run_Day = $aRun_Days[$i]



            ;Запоминаем последний день запуска в ini-файл (на случай перезагрузки компьютера)

            IniWrite($sConfig_File, "Main", "Last Run Day", $sLast_Run_Day)



            ;Задаём иконку значку в трее

            TraySetIcon("Shell32.dll", 246)



            ;Запускаем программы (задачи)

            Local $sTasks = ""



            For $j = 1 To $aRun_Apps[0]

                $sTasks &= $j & ". " & StringRegExpReplace($aRun_Apps[$j], "^.*\\", "") & @CRLF

                Run($aRun_Apps[$j])

            Next



            ;Показываем информацию о запуске

            TrayTip("Планировщик...", "Запущенные задачи: " & @CRLF & $sTasks, 0, 1)



            ;Ждём 3 секунды

            Sleep(3000)



            ;Задаём иконку значку в трее (обратно на изначальную)

            TraySetIcon("Shell32.dll", 25)



            ExitLoop

        EndIf

    Next

EndFunc



Func _Exit()

    Exit

EndFunc

Для пропущенных дней нужно писать отдельную проверку, и как верно заметил Diamond, это уже начинает походить на планировщик задач.