Автоматическое назначение имен дисков
Сделал полностью автоматический диск установки Windows с дровами и программами, но интересует такой вопрос, при установки после полного форматирования системного диска, все диски теряют свои буквы и системой назначаются буквы по алфавиту, потом приходится с помощью Partition Magic менять вручную буквы у дисков. Можно ли задавать метки и буквы для дисков непосредственно в ходе установки?
|
dushes, насчет букв не знаю, но метки можно задать так:
Код:
@echo off
Label C: SYSTEMDISK
Label D: MEDIA
Label E: WORK
exit
|
Метки не самое важно, но спасибо. Важны буквы.
|
Цитата:
Цитата dushes
Можно ли задавать метки и буквы для дисков непосредственно в ходе установки? »
|
Программа установки не предоставляет такой возможности. |
А сторонние утилиты здесь не помогут (по типу учетных записей renuser.exe)?
|
dushes, как вариант можно попробовать с мультибута запустить образ флопика dos, в нем в autoexec.bat запустить format.exe с параметрами, потом winnt.exe с указанием файла ответов.
|
Цитата:
Цитата dushes
все диски теряют свои буквы и системой назначаются буквы по алфавиту, потом приходится с помощью Partition Magic менять вручную буквы у дисков »
|
а что тебя не устраивает, или что ты вообще хочешь получить? C: D: Z: ??? |
С помощью этого скрипта меняю буквы на CD-DVD. Адаптируйте под себя и пользуйтесь.
Код:
@cmdow @ /HID
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
Rem Tip obrabatyvaemyh privodov i vydelennye dlia nih bukvy
SET DRV_TYPE=DVD CD
SET DRV_FREE=Q Z Y
Echo.
Echo.Progress: Proveriaem nalichie DiskPart...
DiskPart.Exe /? >nul 2>&1
IF %ERRORLEVEL% NEQ 0 (
Echo.
Echo.Progress: Fajl DISKPART.EXE ne najden, rabota skripta prervana!
PAUSE
EXIT
)
Echo.Progress: Opredeliaem lokalizaciju DiskPart...
DiskPart.Exe /?|Find "On computer:"
IF %ERRORLEVEL%==0 (
SET POS_VOL=7
SET POS_LTR=13
SET POS_TYP=37
) ELSE (
SET POS_VOL=4
SET POS_LTR=10
SET POS_TYP=34
)
echo.Progress: Vychisliaem kolichestvo propuskaemyh strok...
SET SKIP=0
FOR /F "tokens=1 delims=[]" %%A IN ('@echo list volume^|@diskpart^|find /N "DISKPART>"') Do IF !SKIP! EQU 0 SET /A SKIP=%%A+2
Echo.Progress: Formiruem spisok ustrojstv, fil'truem perenaznachennye ranee...
FOR /F "skip=%SKIP% tokens=*" %%A IN ('@echo list volume^|@diskpart') Do (
SET LINE=%%A
SET DRV_USED=!DRV_USED! !LINE:~%POS_LTR%,1!
CALL :FIND !LINE:~%POS_LTR%,1! "%DRV_FREE%"
IF !ERRORLEVEL!==1 FOR %%B IN (%DRV_TYPE%) DO CALL :TEST_DRIVE %%B
)
IF "%VOL_WORK%"=="" (
echo.
echo.Progress: Spisok perenaznachenija pust^^^! Skript zavershil rabotu.
EXIT
)
Echo.Progress: Vypolniaem perenaznachenie po sformirovannomu spisku...
Echo.
FOR %%A IN (%VOL_WORK%) DO (
CALL :FindNext
CALL :ASSIGN %%A !LTR!
SET DRV_USED=!DRV_USED! !LTR!
)
EXIT
Rem Obrabotka ocherednoj stroki komandy DiskPart "list volume"
:TEST_DRIVE
CALL :LENGTH %~1
IF "%~1"=="!LINE:~%POS_TYP%,%LENGTH%!" SET VOL_WORK=!VOL_WORK! !LINE:~%POS_VOL%,1!
GOTO :EOF
Rem Vychislenie dliny parametra
:LENGTH
SET LENBUF=%~1
SET LENGTH=0
IF "%~1"=="" GOTO :EOF
:LENGTH_START
SET /A LENGTH+=1
IF ""=="!LENBUF:~%LENGTH%,1!" GOTO :EOF
GOTO :LENGTH_START
Rem Vyzov komandy naznachenija
:ASSIGN
(@echo select volume %~1&@echo assign letter=%~2)|diskpart|find /I "DiskPart:"
GOTO :EOF
Rem Vyzov komandy FIND
:FIND
@echo %~2|@find "%~1">nul
GOTO :EOF
Rem Poisk svobodnoj bukvy iz zadannogo mnozestva
:FindNext
For %%i in (%DRV_FREE%) Do (
@echo.%DRV_USED%|Find "%%i">nul
IF !ERRORLEVEL!==1 (
SET LTR=%%i
GOTO :EOF
)
)
Echo.
Echo.Skript prervan^! Spisok svobodnyh bukv ischerpan.
EXIT
|
| Cancer_mvm |
18-06-2009 17:31 1146119 |
Что это за echo файл? и как мне поставить метку системного диска. Из файла winnt.sif не срабатывает
[GuiRunOnce]
"cmd /Q /C label %systemdrive% Wind_XP"
Пробывал еще так
[GuiRunOnce]
"cmd /Q /C label %systemdrive%:Wind_XP"
|
Cancer_mvm,
Цитата:
Цитата Habetdin
[GUIRunOnce]
command1="..."
command2="..."
command3="..."
command4="..." »
|
|
Время: 02:39.
© OSzone.net 2001-
