[DJ Mogarych]

У меня начальные познания о командных файлах »

Переходите на Powershell тогда лучше сразу. Там решена масса проблем CMD.

[megaloman]

Подскажите, в чём фишка употребления CALL в сочетании с другими операторами »

Попытаюсь:

Дело в отложенном раскрытии переменных командной строки.
Вот примеры. Проделайте, проанализируйте. Все эти махинации нужны, чтобы в цикле можно было использовать изменяемые значения переменных.
В 111111 Call не применяли, в результате имеем значение Junk до цикла.
В 222222 используем Call для раскрытия значения переменной внутри цикла,
а в 333333 работаем с переменной Junk внутри вызываемой в цикле процедуры.
В 444444 применяем SetLocal EnableDelayedExpansion для раск для раскрытия значения переменной внутри цикла. Там переменная заключается в знаки !Junk!
При этом возможны неприятности: если в значении переменной присутствует !, то получим непредсказуеый результат.

Код:

@Echo Off
cls
Echo. &Echo ----- 111111 Без Call
	Set "Junk="
	For /L %%i In (100001,100000,400000) Do (
		Set "Junk=%%i"
		Set "Junk=%Junk:~0,-1%"
		Echo i=%%i   Junk="%Junk%"
	)
Echo "%Junk%"

Echo. &Echo ----- 222222 C Call
	Set "Junk="
	For /L %%i In (100001,100000,400000) Do (
		Set "Junk=%%i"
		Call Set "Junk=%%Junk:~0,-1%%"
		Call Echo i=%%i   Junk="%%Junk%%"
	)
Echo "%Junk%"

Echo. &Echo ----- 333333 C процедурой
	Set "Junk="
	For /L %%i In (100001,100000,400000) Do Call :MyEcho %%i
Echo "%Junk%"

Echo. &Echo ----- 444444 SetLocal EnableDelayedExpansion
SetLocal EnableDelayedExpansion
	Set "Junk="
	For /L %%i In (100001,100000,400000) Do (
		Set "Junk=%%i"
		Set "Junk=!Junk:~0,-1!"
		Echo i=%%i   Junk="!Junk!"
	)
Echo "%Junk%"
SetLocal DisableDelayedExpansion

Pause
Exit /B

:MyEcho
	Set "Junk=%1"
	Set "Junk=%Junk:~0,-1%"
	Echo i=%1   Junk="%Junk%"
Exit /B

Аналогичные проблемы при работе с переменными внутри If