[Creat0R]

И как мне вывести в окно сообщения (MsgBox) - первое значение, допустим, из 2 раздела (всего их 5) INI файла - что бы (MsgBox) - находился не в цикле. »

Код:

$aSecondSection = $aAllSections[2]
MsgBox(64, "", $aSecondSection[1][1])

Мне вот так нужно заполнить массив »

Это на мой взгляд сложнее для разбора.

[FlatX007]

Это на мой взгляд сложнее для разбора. »

И всё же можно поправить мой пример ? что бы мне знать.

[Creat0R]

И всё же можно поправить мой пример ? »

Ну он неправильный, как ты будешь различать, к какой секций относится определённое значение?

Можно сделать так например, но это может привести к достижению ограничения в размерности массива:

Код:

#Include <Array.au3>

;~ $sPathIni = @ScriptDir & '\Original Library\Olf.ini'
$sPathIni = @WindowsDir & "\win.ini"
$aSectionNames = IniReadSectionNames($sPathIni)

If Not (@error) Then
    Dim $aArray[$aSectionNames[0]+1][1]

    For $i = 1 To $aSectionNames[0]
        $aIniRead = IniReadSection($sPathIni, $aSectionNames[$i])

        If Not (@error) Then
            ReDim $aArray[$aSectionNames[0]+1][$aIniRead[0][0]+1]
            $aArray[$i][0] = $aSectionNames[$i]

            For $i1 = 1 To $aIniRead[0][0]
                $aArray[$i][$i1] = $aIniRead[$i1][1]
            Next
        EndIf
    Next

    _ArrayDisplay($aArray)
EndIf

[Creat0R]

Или так, где имя секций повторяется для всех её значений:

Код:

#Include <Array.au3>

;~ $sPathIni = @ScriptDir & '\Original Library\Olf.ini'
$sPathIni = @WindowsDir & "\win.ini"
$aSectionNames = IniReadSectionNames($sPathIni)

If Not (@error) Then
    Dim $aArray[1][3]

    For $i = 1 To $aSectionNames[0]
        $aIniRead = IniReadSection($sPathIni, $aSectionNames[$i])

        If Not (@error) Then
            For $i1 = 1 To $aIniRead[0][0]
                $aArray[0][0] += 1
                ReDim $aArray[$aArray[0][0]+1][3]

                $aArray[$aArray[0][0]][0] = $aSectionNames[$i]
                $aArray[$aArray[0][0]][1] = $aIniRead[$i1][0]
                $aArray[$aArray[0][0]][2] = $aIniRead[$i1][1]
            Next
        EndIf
    Next

    _ArrayDisplay($aArray)
EndIf

[FlatX007]

как ты будешь различать, к какой секций относится определённое значение? »

Так я изначально знаю какие секции будут в INI файле , имена ключей мне не нужны, нужна секция и все значения ключей в ней.

Вот теперь то что нужно !

[Andress]

Или так, где имя секций повторяется для всех её значений: »

Кто подскажет как работать с полученной инфой? Найти допустим Имя секций, если такое имеется то найти там параметр, если параметр существует, то считать значение параметра в переменную. имена задаются вручную,только значение параметра надо Узнать.

[Creat0R]

Кто подскажет »

В этой теме никто, т.к оно не связано.

[Andress]

Не понел юмора . Может тогда хоть направление какое?

[kaster]

Andress, создавай новую тему. правило простое: один вопрос - одна тема