[DJ Mogarych]

Powershell:

Код:

$src = "D:\temp\arch"
$dest = "D:\temp\extract"

dir "$src" -file |? extension -match "\.zip|\.rar|\.7z" |% {
$extract = & "C:\Program Files\7-Zip\7z.exe" x "$($_.fullname)" -o"$dest\$($_.basename)"
if ($extract -contains "Everything is Ok") {del "$($_.fullname)"}
}

[megaloman]

Код:

@Echo Off
cls
	Set "BoxArc=Z:\Soft_Arc"
	Set Mask="*.rar" "*.Zip" "*.7z"

	Set "OutBox=Z:\Soft_Out" 

	Set Arc="C:\Program Files\7-Zip.21beta\7z.exe" x -y

	Pushd "%BoxArc%"||(Echo !!! Folder "%BoxArc%" not found &Pause &Exit /B 2)
	If Not Exist "%OutBox%" (Echo !!! Folder "%OutBox%" not found &Pause &Exit /B 2)

	FOR /F "usebackq delims=" %%f In (`2^>nul Dir /B /A:-D %Mask%`) DO (
		Echo "%BoxArc%\%%f"
		>nul %Arc% "%BoxArc%\%%f" -o"%OutBox%\" &&(Del "%BoxArc%\%%f" &&Echo           "%BoxArc%\%%f" deleted)
	)

	Popd
pause
Exit /B

Примечание: этот вариант кода не ломается от присутствия "!" в именах, например:
Set "BoxArc=Z:\!!! Soft_Arc !!!"
Set "OutBox=Z:\!!! Soft_Out !!!"