[gora]

можно ли ускорить данный скрипт ? »

На cmd, вряд ли. Попробуйте на vbs:

Код:

Set FSO = CreateObject("Scripting.FileSystemObject")
infile = "obr.xml"
outfile = "5.txt"
find1 = "<signature>"
replace1 = "<img src=""data:image/png;base64,"
find2 = "</signature>"
replace2 = """ />"
find3 = "<portrait>"
replace3 = "<img src=""data:image/png;base64,"
find4 = "</portrait>"
replace4 = """ />"

strt = Now

Set rd_file = FSO.OpenTextFile(infile, 1,, -2)
Buffer = rd_file.ReadAll
rd_file.Close
size1 = Len(Buffer)

Buffer = Replace(CStr(Buffer), find1, replace1, 1, -1, 1)
Buffer = Replace(CStr(Buffer), find2, replace2, 1, -1, 1)
Buffer = Replace(CStr(Buffer), find3, replace3, 1, -1, 1)
Buffer = Replace(CStr(Buffer), find4, replace4, 1, -1, 1)

Set wr_file = FSO.OpenTextFile(outfile, 2, True)
wr_file.Write Buffer
wr_file.Close
size2 = Len(Buffer)

fnsh = Now

MsgBox "Размер файла до -		" & size1 & vbCr _
	& "Размер файла после -	" & size2 & vbCr _
	& "Время работы -		" & DateDiff("s",strt,fnsh) & " с", 64, "Замены произведены"
WScript.Quit

Файл в 3МБ у меня обрабатывает ~ 1с.

[dark-------13]

Спасибо большое уважаемый Gora, в очередной раз выручаете меня!

[apozlevich]

Оптимизировать bat, оптимизировать vbs... Если хотите скорость - пишите на C.