CMD/BAT - [решено] Сложное пакетное переимеонование

Foreigner · Отправлено: **09:39, 25-08-2012** | #2

Aleksander.Ruban@fb,
Попробуй:

Код:

@echo off
setlocal

pushd "C:\2007" || goto:eof

for %%i in (EUR MULTI USA) do (

    for /f "tokens=*" %%j in ('dir /b /ad *%%i*') do call:1 %%i "%%j"

)

popd
goto:eof

:1

set "name=%~2"
set "name=%name:EUR=?%"
set "name=%name:MULTI=?%"
set "name=%name:USA=?%"

for /f "tokens=1 delims=?" %%i in ("%name%") do set "name=%%i(%1)"

ren "%~2\psy-boe.cso" "%name:_= %.sco"

Если название файла sco заранее не известно, то можно заменить последнюю строчку на:

Код:

for %%i in ("%~2\*.sco") do (

    ren "%%i" "%name:_= %.sco"
    1>"%~2\orig_name.txt" echo %%~nxi

)

Aleksander.Ruban@fb · Отправлено: **12:01, 25-08-2012** | #3

Цитата Foreigner:

@echo off
setlocal
pushd "C:\2007" || goto:eof
for %%i in (EUR MULTI USA) do (
for /f "tokens=*" %%j in ('dir /b /ad *%%i*') do call:1 %%i "%%j"
)
popd
goto:eof
:1
set "name=%~2"
set "name=%name:EUR=?%"
set "name=%name:MULTI=?%"
set "name=%name:USA=?%"
for /f "tokens=1 delims=?" %%i in ("%name%") do set "name=%%i(%1)"
ren "%~2\psy-boe.cso" "%name:_= %.sco"
»

Отлично! Только в последней строке (ren "%~2\psy-boe.cso" "%name:_= %.sco") надо сменить %.sco на %.cso.
Но не понял, как заставить работать скрипт, если имя файла неизвестно.

В таком варианте:

Цитата Foreigner:

@echo off
setlocal
pushd "C:\2007" || goto:eof
for %%i in (EUR MULTI USA) do (
for /f "tokens=*" %%j in ('dir /b /ad *%%i*') do call:1 %%i "%%j"
)
popd
goto:eof
:1
set "name=%~2"
set "name=%name:EUR=?%"
set "name=%name:MULTI=?%"
set "name=%name:USA=?%"
for /f "tokens=1 delims=?" %%i in ("%name%") do set "name=%%i(%1)"
for %%i in ("%~2\*.sco") do (
ren "%%i" "%name:_= %.sco"
1>"%~2\orig_name.txt" echo %%~nxi
)
»

После запуска перименование не происходит.
Еще вопрос в первом варианте скобка ")" в конце нужна?
Прим. Сейчас узрел ошибки cso-sco. Подправлю отпишусь.

Foreigner · Отправлено: **12:05, 25-08-2012** | #4

Цитата Aleksander.Ruban@fb:

После запуска перименование не происходит.
Еще вопрос в первом варианте скобка ")" в конце нужна? »

Может тоже cso. Скобка нужна

Aleksander.Ruban@fb · Отправлено: **12:23, 25-08-2012** | #5

В таком варианте работает.

Цитата:

@echo off
setlocal
pushd "C:\2007" || goto:eof
for %%i in (EUR MULTI USA) do (
for /f "tokens=*" %%j in ('dir /b /ad *%%i*') do call:1 %%i "%%j"
)
popd
goto:eof
:1
set "name=%~2"
set "name=%name:EUR=?%"
set "name=%name:MULTI=?%"
set "name=%name:USA=?%"
for /f "tokens=1 delims=?" %%i in ("%name%") do set "name=%%i(%1)"
for %%i in ("%~2\*.cso") do (
ren "%%i" "%name:_= %.cso"
1>"%~2\orig_name.txt" echo %%~nxi
)

Но один из файлов в orig_name.txt переносится не в оригинальном виде, а в виде имени уже переименованого файла.
Например, вместо "su-frantix.cso" в orig_name.txt записалось "Frantix.(EUR).cso". Кстати, сам файл переименован в "Frantix.(MULTI).cso". Точка перед (MULTI) и (EUR) лишняя, да и почему нессотвествие (MULTI) и (EUR)? В остальных случаях в orig_name.txt записались исходные (правильные, не переименованные) имена. Проверил несколько раз - всегда один из файлов неверно записывается в orig_name.txt. Проблема в том, что непонятно в какой именно... Переименование происходит не по алфавиту.
И еще скрипт в конце (перед закрытием) заканчивается выводом сообщения "file not found"

Foreigner · Отправлено: **13:06, 25-08-2012** | #6

Я не смог повторить, у меня все нормально. Сделайте листинг тестовой директории:

Код:

dir /b /s c:\2007\*.cso > file.txt

И выложите. Может какие-нибудь проблемы в названиях?

Aleksander.Ruban@fb · Отправлено: **13:27, 25-08-2012** | #7

Удалено. Дубль сваял.

Aleksander.Ruban@fb · Отправлено: **13:52, 25-08-2012** | #8

Листинг
До переименования

и после

Не переименовался файл в дир-ии Namco_Museum_Battle_Collection_Pal_PSP-eLk - Pal записан нестандартно (можно добавить).
В имени Bomberman.(EUR).cso перед (EUR) затесалась точка.
В папке "c:\2007\Frantix.EUR.MULTI5.PSP-SUSHi\Frantix.(MULTI).cso" в файл "orig_name.txt" вместо "su-frantix.cso" записалось "Frantix.(EUR).cso". Это тестовый набор папок. Я пробовал еще на одном - тоже в один из файлов "orig_name.txt" вместо первоначального имени записалось переименованное.

Вариант 2

и после -

В папках "Cars_Race_o_Rama_EUR_PSP-BAHAMUT" и "Elementalmonster_TD_Portable_EUR_MULTi5_PSN_PSP-NRP" в файлах "orig_name.txt" вместо "b-carsrorepsp.cso" и "nrp-emtdpe.cso" записалось соотвественно "Cars Race o Rama (EUR).cso" и "Elementalmonster TD Portable (EUR).cso".
Может не успевает скрипт, задержка нужна?

Foreigner · Отправлено: **14:14, 25-08-2012** | #9

Aleksander.Ruban@fb,
Разобрался. Директории, в названиях которых есть и EUR и MULTI и USA одновременно, обрабатываются несколько раз, из-за этого файлы переименовываются тоже несколько раз. Измени последний for

Код:

for %%i in ("%~2\*.cso") do (

    if not exist "%~2\orig_name.txt" (
    
    ren "%%i" "%name:_= %.cso"
    1>"%~2\orig_name.txt" echo %%~nxi

))

ЗЫ. Соответственно c:\2007\Namco_Museum_Battle_Collection_Pal_PSP-eLk\c-nmpsp.cso вообще не обрабатывается, т.к. не соответствует условиям поиска (USA MULTI EUR)
ЗЫЫ. "file not found" если есть директория, в названии которой отсутствуют EUR, MULTI или USA.

Aleksander.Ruban@fb · Отправлено: **20:11, 25-08-2012** | #10

Спасибо. Вы гений! Все сработало прекрасно: 1050 каталогов (460 гигов) переименовались в течении 1 минуты.