CMD/BAT

megaloman · Отправлено: **11:41, 07-06-2012** | #2

Код:

FOR %%D IN (Yes No Help) DO FOR /F "usebackq delims=" %%i IN (`dir "C:\Hello\%%D\" /b /A:D /S`) DO @Echo %%i

или, в зависимости от Ваших обстоятельств,

Код:

FOR %%D IN (Yes No Help) DO FOR /F "usebackq delims=" %%i IN (`dir "C:\Hello\%%D\111\" /b /A:D /S`) DO @Echo %%i

Код:

@Echo Off
FOR /F "usebackq delims=" %%D IN (`dir "C:\Hello\" /b /A:D`) DO (
	FOR /F "usebackq delims=" %%i IN (`dir "C:\Hello\%%D\111\" /b /A:D /S`) DO @Echo %%i
)

Bukinozoid · Отправлено: **09:26, 08-06-2012** | #3

Первые два не катят, так как папок очень много и смысл маски пропадает, а вот в последний не пойму куда действие запихнуть, чтоб удалялись папки 123, 456 и 789?

megaloman · Отправлено: **18:51, 08-06-2012** | #4

Если убить все директории ниже 111\, то

Код:

@Echo Off
FOR /F "usebackq delims=" %%D IN (`dir "C:\Hello\" /b /A:D`) DO (
	FOR /F "usebackq delims=" %%i IN (`dir "C:\Hello\%%D\111\" /b /A:D`) DO Rd C:\Hello\%%D\111\%%i /S /Q
)

Если некоторые определённые, то

Код:

@Echo Off
FOR /F "usebackq delims=" %%D IN (`dir "C:\Hello\" /b /A:D`) DO (
     Rd C:\Hello\%%D\111\123 /S /Q
     Rd C:\Hello\%%D\111\456 /S /Q
     Rd C:\Hello\%%D\111\789 /S /Q
)

или

Код:

@Echo Off
FOR /F "usebackq delims=" %%D IN (`dir "C:\Hello\" /b /A:D`) DO (
     FOR %%i IN ("123" "456" "789") DO If Exist "C:\Hello\%%D\111\%%~i" Rd "C:\Hello\%%D\111\%%~i" /S /Q
)

Если конечно не надо иметь жесткой связки Yes-123 No-456 Help-789, в противном случае задача о маске теряет смысл, придётся как-то описывать каждую пару папок.

Bukinozoid · Отправлено: **09:24, 09-06-2012** | #5

megaloman, спасибо Вам большое!!!