[решено] Сбор информации с сайта и ее обработка.

Creat0R · Конфигурация компьютера

Цитата:

$Sourse = _INetGetSource ($URL)

А где ссылка?

Medic84 · Отправлено: **15:31, 18-08-2009** | #3

Извиняюсь..

Код:

http://www.kinopoisk.ru/level/1/film/397496/

Вот ссылка

Creat0R · Конфигурация компьютера

Medic84, На будущее, всегда выкладывай рабочий пример, в твоём коде также нехватает инклюда Inet.au3.

Цитата Medic84:

Вот ссылка »

По этой ссылке нужно делать запрос, там так просто через исходник не получить нужную страничку.

P.S
А в чём смысл замены пробела на пробел?

Medic84 · Отправлено: **16:11, 18-08-2009** | #5

Цитата Creat0R:

P.S
А в чём смысл замены пробела на пробел? »

Да это форум обрабатывает Html код там написанный. Там по идее & nbsp; Только без пробела

Цитата Creat0R:

По этой ссылке нужно делать запрос, там так просто через исходник не получить нужную страничку. »

Всмысле? Что за запрос?

Цитата Creat0R:

На будущее, всегда выкладывай рабочий пример, в твоём коде также нехватает инклюда Inet.au3. »

Хорошо

Creat0R · Конфигурация компьютера

Цитата Medic84:

Всмысле? Что за запрос? »

Ну а как ты получаешь исходник того, что видишь в браузере? Попробуй сохранить $Source в файл «test.html» и запустить его, у меня лично страница с запросом поиска не получается...

Medic84 · Отправлено: **16:27, 18-08-2009** | #7

В опере нажимаю "Исходный код".
Думаешь через IE нужно страницу сохранять?

З.Ы.
А ты пробовал слеш убирать?

Creat0R · Конфигурация компьютера

Цитата Medic84:

А ты пробовал слеш убирать? »

Пробовал, тоже самое.

Вобщем вот рабочий вариант получения информации о фильме по ссылке. Исходник добывается извращённым путём - через скрытую инстанцию браузера IE

Код:

#include <IE.au3>

$sURL = "http://www.kinopoisk.ru/level/1/film/333416/"

$sURL = InputBox("Kinopoisk.ru Informer", "Введите ссылку на фильм для получения информации:", $sURL, "", 350, 200)
If @error Then Exit

$oIE = _IECreate($sURL, 0, 0)
$sSource = _IEDocReadHTML($oIE)
_IEQuit($oIE)

$sName = _GetSourceProperty($sSource, '', '(?si).*?<h1 class=moviename-big.*?>(.*?)</h1>.*')
$sSlogan = _GetSourceProperty($sSource, 'слоган')
$sBudget = _GetSourceProperty($sSource, 'бюджет')
$sYear = _GetSourceProperty($sSource, 'год')
$sCountry = _GetSourceProperty($sSource, 'страна')
$sDirector = _GetSourceProperty($sSource, 'режиссер')
$sUSA_Collect = _GetSourceProperty($sSource, 'сборы в США')
$sWorld_Collect = _GetSourceProperty($sSource, 'сборы в мире')
$sRus_Collect = _GetSourceProperty($sSource, 'сборы в России')
$sTime = _GetSourceProperty($sSource, 'время')

$aJanrs = StringRegExp($sSource, '.*?<A href="/level/10/.*?genre.*?">(.*?)</A>.*?', 3)
$sJanrs = ""
$iUbound = UBound($aJanrs)-1

For $i = 0 To $iUbound
    $sJanrs &= $aJanrs[$i]
    If $i < $iUbound Then $sJanrs &= ", "
Next

$sInfo = StringFormat( _
    "Имя:\t\t\t%s\n" & _
    "Слоган:\t\t\t%s\n" & _
    "Бюджет:\t\t\t%s\n" & _
    "Год:\t\t\t%s\n" & _
    "Страна:\t\t\t%s\n" & _
    "Режиссер:\t\t%s\n" & _
    "Сборы в США:\t\t%s\n" & _
    "Сборы в мире:\t\t%s\n" & _
    "Сборы в России:\t\t%s\n" & _
    "Время:\t\t\t%s\n\n" & _
    "Жанр:\t\t\t%s", _
    $sName, $sSlogan, $sBudget, $sYear, $sCountry, $sDirector, $sUSA_Collect, $sWorld_Collect, $sRus_Collect, $sTime, $sJanrs)

MsgBox(64, 'Kinopoisk.ru Info', $sInfo)

;Функция для получения подстроки по заданному pattern
Func _GetSourceProperty($sSource, $sName, $sPattern='')
    Local $s_Pattern = '(?si).*?<TD class=type>%s</TD>.*?<TD(?: class=.*?|)>(?:<A href=".*?">|)(.*?)(?:</A>|)</TD></TR>.*'
    If $sPattern <> '' Then $s_Pattern = $sPattern

    $s_Pattern = StringFormat($s_Pattern, $sName)

    Local $sRet = StringRegExpReplace($sSource, $s_Pattern, '\1')
    If @extended = 0 Then Return SetError(1, 0, "N/A")

    $sRet = StringReplace($sRet, ' ', ' ')
    $sRet = StringRegExpReplace($sRet, '\A«+|»+$', '"')

    Return $sRet
EndFunc

Medic84 · Отправлено: **18:01, 18-08-2009** | #9

Если бы можно было оценку поставить поставил бы 10 баллов!

Medic84 · Отправлено: **20:53, 18-08-2009** | #10

Хех. Пытался вставить свое и свое ничего не работает. Кроме краткого....
Причем в твоем скрипте "Имя" не работает.

Код:

#include <IE.au3>

$sURL = "http://www.kinopoisk.ru/level/1/film/5090/"

$sURL = InputBox("Kinopoisk.ru Informer", "Введите ссылку на фильм для получения информации:", $sURL, "", 350, 200)
If @error Then Exit

$oIE = _IECreate($sURL, 0, 0)
$sSource = _IEDocReadHTML($oIE)
_IEQuit($oIE)

$sName = _GetSourceProperty($sSource, '', '(?si).*?<h1 class=moviename-big>(.*?)</h1>.*')
$sSlogan = _GetSourceProperty($sSource, 'слоган')
$sBudget = _GetSourceProperty($sSource, 'бюджет')
$sYear = _GetSourceProperty($sSource, 'год')
$sCountry = _GetSourceProperty($sSource, 'страна')
$sMir = _GetSourceProperty($sSource, 'премьера (мир)')
$sRF = _GetSourceProperty($sSource, 'премьера (РФ)')
$sOriginal = _GetSourceProperty($sSource, '','?si).*?<span style="color:.*? font-size:.*?">(.*?)</span>.*')
$sDirector = _GetSourceProperty($sSource, 'режиссер')
$sWorld_Collect = _GetSourceProperty($sSource, 'сборы в мире')
$sTime = _GetSourceProperty($sSource, 'время')
$aJanrs = StringRegExp($sSource, '.*?<A href="/level/10/.*?genre.*?">(.*?)</A>.*?', 3)
$sJanrs = ""
$Kratk = _GetSourceProperty($sSource, '','(?si).*?<span class=_reachbanner_.*?>(.*?)</span>.*')
$Kratk = StringReplace($Kratk,"<BR>",@CRLF)
$iUbound = UBound($aJanrs)-1
For $i = 0 To $iUbound
    $sJanrs &= $aJanrs[$i]
    If $i < $iUbound Then $sJanrs &= ", "
    Next

$sInfo = StringFormat( _
    "Имя:\t\t\t%s\n" & _
    "Слоган:\t\t\t%s\n" & _
    "Бюджет:\t\t\t%s\n" & _
    "Год:\t\t\t%s\n" & _
    "Страна:\t\t\t%s\n" & _
    "Режиссер:\t\t%s\n" & _
    "Премьера (Мир):\t\t%s\n" & _
    "Сборы в мире:\t\t%s\n" & _
    "Премьера (РФ):\t\t%s\n" & _
    "Время:\t\t\t%s\n\n" & _
    "Жанр:\t\t\t%s", _
    $sName, $sSlogan, $sBudget, $sYear, $sCountry, $sDirector, $sMir, $sWorld_Collect, $sRF, $sTime, $sJanrs)

MsgBox(64, 'Kinopoisk.ru Info', $sInfo)

;Функция для получения подстроки по заданному pattern
Func _GetSourceProperty($sSource, $sName, $sPattern='')
    Local $s_Pattern = '(?si).*?<TD class=type>%s</TD>.*?<TD(?: class=.*?|)>(?:<A href=".*?">|)(.*?)(?:</A>|)</TD></TR>.*'
    If $sPattern <> '' Then $s_Pattern = $sPattern

    $s_Pattern = StringFormat($s_Pattern, $sName)

    Local $sRet = StringRegExpReplace($sSource, $s_Pattern, '\1')
    If @extended = 0 Then Return SetError(1, 0, "N/A")

    $sRet = StringReplace($sRet, ' ', ' ')
    $sRet = StringRegExpReplace($sRet, '\A«+|»+$', '"')

    Return $sRet
EndFunc

З.Ы. А что делать если несколько режисеров?