[Yashied]

Если ты копируешь шрифт непосредственно в папку ...\WINDOWS\Fons, то в реестр не нужно ничего добавлять, оно само добавится.

[Creat0R]

Если ты копируешь шрифт непосредственно в папку ...\WINDOWS\Fons, то в реестр не нужно ничего добавлять, оно само добавится. »

Но тем не менее шрифт не устанавливается как положенно, я использую такую функцию:

Код:

_FileFontInstall(@ScriptDir & "\Ethnocentric.ttf", "AutoIt Font")
ConsoleWrite(@error)

Func _FileFontInstall($sSourceFile, $sFontDescript="", $sFontsPath="")
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D

    If $sFontsPath = "" Then $sFontsPath = @WindowsDir & "\fonts"

    Local $sFontName = StringRegExpReplace($sSourceFile, "^.*\\", "")
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontName, 1) Then Return SetError(1, 0, 0)

    Local $hSearch = FileFindFirstFile($sSourceFile)
    Local $iFontIsWildcard = StringRegExp($sFontName, "\*|\?")
    Local $aRet, $hGdi32_DllOpen = DllOpen("GDI32.dll")

    If $hSearch = -1 Then Return SetError(2, 0, 0)
    If $hGdi32_DllOpen = -1 Then Return SetError(3, 0, 0)

    While 1
        $sFontName = FileFindNextFile($hSearch)
        If @error Then ExitLoop

        If $iFontIsWildcard Then $sFontDescript = StringRegExpReplace($sFontName, "\.[^\.]*$", "")

        $aRet = DllCall($hGdi32_DllOpen, "Int", "AddFontResource", "str", $sFontsPath & "\" & $sFontName)
        If IsArray($aRet) And $aRet[0] > 0 Then
            RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", _
                $sFontDescript, "REG_SZ", $sFontsPath & "\" & $sFontName)
        EndIf
    WEnd

    DllClose($hGdi32_DllOpen)
    DllCall("User32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
    Return 1
EndFunc

Ethnocentric.ttf

[FlatX007]

Пасиба работает

Но "косячок" один ...если шрифт переименован и в папке Font есть с таким же названием ... то ничего непоставится. Я думаю сравнивать по метаданным (в свойствах файла) - но этоя уже сам.

[FlatX007]

А как правильно удалить шрифт ?

Удаляю из папки и из реестра он всё равно числится в списке ... и даже открывается.

[Creat0R]

как правильно удалить шрифт ? »

Примерно так:

Код:

Func _FileFontUnInstall($sFontFile)
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D

    Local $sFontsPath = @WindowsDir & "\fonts"
    Local $sFontName = StringRegExpReplace($sFontFile, "^.*\\", "")
    If @extended Then $sFontsPath = StringRegExpReplace($sFontFile, "\\[^\\]*$", "")

    Local $aRet = DllCall("Gdi32.dll", "Int", "RemoveFontResourceW", "wstr", $sFontsPath & "\" & $sFontName)

    If IsArray($aRet) And $aRet[0] > 0 Then
        Local $iEnum = 0, $sRegVal = "", $sRegRead
        Local $sRegFontsPath = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts"

        While 1
            $iEnum += 1
            $sRegVal = RegEnumVal($sRegFontsPath, $iEnum)
            If @error <> 0 Then ExitLoop

            $sRegRead = RegRead($sRegFontsPath, $sRegVal)

            If $sRegRead = $sFontsPath & "\" & $sFontName Or $sRegRead = $sFontName Then
                RegDelete($sRegFontsPath, $sRegVal)
                DllCall("User32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
                ExitLoop
            EndIf
        WEnd
    EndIf

    Return 1
EndFunc