[Iska]

Maza11, а если «в текущий день» ему по каким-то причинам не удастся отработать — что тогда? Скриншоты так и останутся «висеть». Надо не с текушей датой создавать, а перебирать все скриншоты, по шаблону имени создавать папку (если ещё не создана) и перемещать в неё скриншот. Я бы делал так.

[Maza11]

а если «в текущий день» ему по каким-то причинам не удастся отработать — что тогда? Скриншоты так и останутся «висеть». Надо не с текушей датой создавать, а перебирать все скриншоты, по шаблону имени создавать папку (если ещё не создана) и перемещать в неё скриншот. Я бы делал так. »

Вы правы, но создание шаблона наверно сложно, я со скриптами совсем не дружу. Поэтому составил задание попроще.

[Iska]

На WSH:

Скрытый текст

Код:

Option Explicit

Dim strSourceFolder

Dim objFSO
Dim objFile

Dim strDestFolder


If WScript.Arguments.Count = 1 Then
	strSourceFolder = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FolderExists(strSourceFolder) Then
		With WScript.CreateObject("VBScript.RegExp")
			.Pattern = "^Snap - (\d{4}-\d{2}-\d{2}) \d{2}\.\d{2}\.\d{2}\.png$"
			.IgnoreCase = True
			
			For Each objFile In objFSO.GetFolder(strSourceFolder).Files
				If .Test(objFile.Name) Then
					strDestFolder = objFSO.BuildPath(strSourceFolder, .Execute(objFile.Name).Item(0).Submatches(0))
					
					If Not objFSO.FolderExists(strDestFolder) Then
						objFSO.CreateFolder strDestFolder
					End If
					
					objFile.Move strDestFolder & "\"
				End If
			Next
		End With
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source folder>"
	WScript.Quit 1
End If

WScript.Quit 0

Путь к исходной папке указывается аргументом скрипта.

[Maza11]

Цитата Iska:
Путь к исходной папке указывается аргументом скрипта. »
что такое аргумент скрипта, в свойствах задания в планировщике указать C:\move.vbs "\\Backup\box\" ???

[Maza11]

в задании прописал C:\move.vbs "\\Backup\box\"
ругается
Usage: cscript.exe //nologo "move.vbs" <Source folder>
как указать ему папку ?

[Iska]

Сделайте экспорт задания в xml и выложите сюда.

[Maza11]

Сделайте экспорт задания в xml и выложите сюда. »

у меня Win XP, не нашел я там экспорта заданий в xml
если на скрипт перетянуть папку с файлами, то он отрабатывает. Внутри создались папки с датами и файлики переместились, круто. Только осталось с планировщиком разобраться/ Может он UNC путь не понимает, т.к. перетягиванием папки на скрипт я занимался локально.

скрин

[alpap]

Maza11,
в планировщике в папке где задание на самой строке задания правой клавишей мыши и выбрать в меню пункт экспортировать, разве нет такого в XP?

[megaloman]

Вот CMD-скрипт

Код:

@Echo Off

Set "BoxIn=\\TOSHIBA\Test1"
Set "BoxOut=\\TOSHIBA\Test1"

Set "Mask=Snap - 20??-??-?? ??.??.??.png"

FOR /F "usebackq delims=" %%f IN (`Dir "%BoxIn%\%Mask%" /b /A:-D 2^>nul`) DO (
	FOR /F "usebackq tokens=3 delims= " %%d IN ('%%f') DO (
		If Not Exist "%BoxOut%\%%d" Md "%BoxOut%\%%d"
		Copy "%BoxIn%\%%f" "%BoxOut%\%%d\" >nul &&Del "%BoxIn%\%%f"
	)
)

Настройте планировщик на его выполнение, в XP, мне помнится, это не проблема, сделайте повтор его исполнения с нужной Вам периодичностью, хоть сто раз в день, хоть раз в неделю, месяц итд. Не на чем вспомнить XP. Пытаюсь по Вашему скрину: кажется, в панели управления найти назначенные задания -> кнопка (иконка?) новое задание ->выдаст окно поиска исполнимого файла. Затем настроите расписание. Там всё понятно