CMD/BAT

megaloman · Отправлено: **16:15, 28-08-2014** | #2

Цитата:

как найти папку зная только половину ее названия ... как зайти в эту папку зная только 2 часть ее названия

Код:

@Echo Off
cls

FOR /D /R "D:\Kuku" %%i IN ("*.Default Main") DO (
	Echo %%i
	Cd /d %%i
	Dir *.*
)

Цитата:

как можно зайти заменить файл с название Remember.inf

Объясните, КАК Вы собираетесь его заменить и насколько принципиально, чтобы первая часть названия папки состояла из 8 символов.

Georgio · Отправлено: **16:24, 28-08-2014** | #3

Код:

@echo off

set "directory_for_search=D:\Test"
set "mask=*.Default Main"
set "file_to_copy=E:\Remember.inf"

for /f "delims=" %%i in ('
 dir /ad/b/s "%directory_for_search%\%mask%"^| findstr /rc:"\\........\%mask:~1%$"
') do (
 start "" explorer "%%i"
 >nul timeout /t 5
 start "" cmd /c "copy "%file_to_copy%" "%%i"& >nul timeout /t 5"
 )

exit /b

Gisender · Отправлено: **16:57, 28-08-2014** | #4

Спасибо,а можно сделать так что бы копировался не 1 ,а 2 файла,да первый файл просто по пути *.Default Main\Remember.ini ,а второй *.Default Main\Redist\SettingsManager.ini
И да как можно убрать открытие найденной папки,не нужно что бы выскакивала в проводнике

Georgio · Отправлено: **17:41, 28-08-2014** | #5

Код:

@echo off

set "directory_for_search=D:\Test"
set "mask=*.Default Main"

set "file_to_copy_1=E:\Remember.ini"
set "destination_folder_1=."

set "file_to_copy_2=E:\SettingsManager.ini"
set "destination_folder_2=Redist"

for /f "delims=" %%i in ('
 dir /ad/b/s "%directory_for_search%\%mask%"^| findstr /rc:"\\........\%mask:~1%$"
') do (
 copy "%file_to_copy_1%" "%%i\%destination_folder_1%"
 copy "%file_to_copy_2%" "%%i\%destination_folder_2%"
 )

>nul timeout /t 5
exit /b

Цитата Gisender:

а лучше вместо копирования создавался с текстом »

Приведите нужный текст для обоих файлов.

Gisender · Отправлено: **17:53, 28-08-2014** | #6

Цитата Georgio:

Приведите нужный текст для обоих файлов. »

Да я так подумал,не стоит тексе,лучше просто копирование

Gisender · Отправлено: **11:20, 04-01-2015** | #7

Здравствуйте давно не заходил,нужна помощь к вашему батнику ниже,нужно кое что дописать,а именно что бы в начале перед копированием создавалась папка в этой директориии "set "destination_folder_1=."" и удалялся с этой же директории файл с именем prefs.js,а уже после начиналось копирование

Цитата Georgio:

@echo off
set "directory_for_search=D:\Test"
set "mask=*.Default Main"
set "file_to_copy_1=E:\Remember.ini"
set "destination_folder_1=."
set "file_to_copy_2=E:\SettingsManager.ini"
set "destination_folder_2=Redist"
for /f "delims=" %%i in ('
dir /ad/b/s "%directory_for_search%\%mask%"^| findstr /rc:"\\........\%mask:~1%$"
') do (
copy "%file_to_copy_1%" "%%i\%destination_folder_1%"
copy "%file_to_copy_2%" "%%i\%destination_folder_2%"
)
>nul timeout /t 5
exit /b »