CMD/BAT - [решено] Как вывести в лог значения из arp -a

amel27 · Отправлено: **12:50, 11-07-2011** | #2

Код:

@echo off
SETLOCAL EnableDelayedExpansion
(
echo:ip              mac
echo:
for /f "tokens=1,2" %%a in ('arp -a^|findstr/brc:" *[0-9]"') do (
 set "$a=%%a        "& set "$b=%%b"
 echo !$a:~,15! !$b:-=!
))>arp.log

amel27 · Отправлено: **18:04, 11-07-2011** | #3

Цитата root221:

сейчас наблюдается такая картина »

да нет, код из поста #2 у меня даёт ровные столбцы

Цитата root221:

Буквы которые в мак адресе были большими »

Код:

@echo off
SETLOCAL EnableDelayedExpansion
(echo:IP Машины       Мак адрес
 echo:
 for /f "tokens=1,2" %%a in ('arp -a^|findstr/brc:" *[0-9]"') do (
  set "$a=%%a        "& set "$b=%%b"
  for %%x in ("a=A" "b=B" "c=C" "d=D" "e=E" "f=F") do set "$b=!$b:%%~x!"
  echo !$a:~,15! !$b:-=!
))>arp.log

amel27 · Отправлено: **04:25, 12-07-2011** | #4

Цитата root221:

в список добавлялся новый компьютер если тот появился в arp -a »

Цитата root221:

если например в списке есть адрес с нулевым мак адресом то его в список не заносить »

Код:

@echo off
SETLOCAL EnableDelayedExpansion
::-------------
set LOG=arp.log
::-------------
if not exist "%LOG%" (echo:IP Машины       Мак адрес&echo:)>"%LOG%"
(for /f "tokens=1,2" %%a in ('arp -a^|findstr/brc:" *[0-9]"') do (set "$b=%%b"
 set "$a=%%a        "& set "$a=!$a:~,15!"
 for %%x in ("-=" "a=A" "b=B" "c=C" "d=D" "e=E" "f=F") do set "$b=!$b:%%~x!"
 if not "!$b!"=="000000000000" findstr/ei "!$b!" "%LOG%">nul||echo !$a! !$b!
))>>"%LOG%"

Цитата root221:

в этойже последовательности »

тогда уже не "добавить" (в конец текущего файла), а "вставить" в середину списка, что потребует копирования, удаления и повторного создания всего файла... например, путём сортировки (SORT /?)

Цитата root221:

и так сойдёт >

не сойдет, так как выравнивание делает целая строка кода (выделена синим):
1) добавление в конец IP-адреса 8 пробелов,
2) обрезание строки по длине 15 символов.

amel27 · Отправлено: **06:19, 12-07-2011** | #5

root221, как вариант:

Код:

@echo off
SETLOCAL EnableDelayedExpansion
::путь\имя лог-файла
set LOG=arp.log
::запись IP/MAC в переменные $$*
for /f "tokens=1,2" %%a in ('"(type "%LOG%"& arp/a)|findstr/brc:" *[0-9]""') do (
  set "$a=%%a        "& set "$a=!$a:~,15!"& set "$b=%%b"
  for %%x in ("-=" "a=A" "b=B" "c=C" "d=D" "e=E" "f=F") do set "$b=!$b:%%~x!"
  if not "!$b!"=="000000000000" set "$$!$b!=!$a!")
::вывод заголовка в новый файл
(echo:IP Машины       Мак адрес& echo:)>"%LOG%"
::добавление IP/MAC в файл (с сортировкой)
(for /f "tokens=1,2 delims==$" %%x in ('set $$') do @echo %%y %%x
)|sort >>"%LOG%"

amel27 · Отправлено: **06:59, 12-07-2011** | #6

Цитата root221:

можно както зделать чтобы он записывал все данные из лога в переменную
и потом просто записывал все данные занова с добавлением новых »

в #8 так и сделано - добавил комментарий

amel27 · Отправлено: **07:29, 12-07-2011** | #7

Цитата root221:

создаётся не попорядку »

сортировка сделана тупо по IP-адресам, а как надо?
...можете проверить сами (без учета заголовка):

Код:

sort ARP.LOG

root221 · Отправлено: **07:30, 12-07-2011** | #8

Код:

10.0.0.1     001234567890
10.0.0.108  001234567890
10.0.0.11    001234567890
10.0.0.111   001234567890

Код:

а надо

 10.0.0.1 001234567890
 10.0.0.2 001234567890
 10.0.0.3 001234567890
 10.0.0.4 001234567890

и пошло поехало

последние цифры ip адреса хотелось бы чтобы шли по порядку, как показанно в примере выше

amel27 · Отправлено: **08:21, 12-07-2011** | #9

root221, о том и речь, что сортировка может быть разной:

Код:

@echo off
SETLOCAL EnableDelayedExpansion
::путь\имя лог-файла
set LOG=arp.log
::сохранение IP/MAC в переменных $$*
for /f "tokens=1,2" %%a in ('"(type "%LOG%"&arp/a)|findstr/brc:" *[0-9]""') do (
  set "$a=%%a        "& set "$a=!$a:~,15!"& set "$b=%%b"& set "$="
  for %%x in ("-=" "a=A" "b=B" "c=C" "d=D" "e=E" "f=F") do set "$b=!$b:%%~x!"
  if not "!$b!"=="000000000000" (for %%x in (00!$a:.^= 00!) do set "$x=%%x"& set "$=!$!!$x:~-3!"
  set "$$!$!=!$a! !$b!"))
::вывод в файл
(echo:IP Машины       Мак адрес& echo:
 for /f "tokens=1* delims==" %%x in ('set $$') do echo %%y
)>"%LOG%"

P.S. При смене IP машины вариант #8 корректно исправит адрес для заданного MAC в списке, в этом варианте будет добавлена новая запись, старая будет висеть пока адрес не займёт другой хост. Так как 1-й скрипт отталкивается от MAC, второй - от IP.

amel27 · Отправлено: **09:20, 13-07-2011** | #10

Цитата root221:

если мак адрес машины изменился»

может IP адрес?

Код:

@echo off
SETLOCAL EnableDelayedExpansion
::путь\имя лог-файла
set LOG=arp.log
::сохранение IP/MAC в переменных $$*
for /f "tokens=1,2" %%a in ('"(arp/a&type "%LOG%")|findstr/brc:" *[0-9]""') do (
  set "$a=%%a        "& set "$a=!$a:~,15!"& set "$b=%%b"& set "$="
  for %%x in ("-=" "a=A" "b=B" "c=C" "d=D" "e=E" "f=F") do set "$b=!$b:%%~x!"
  for %%x in (00!$a:.^= 00!) do set "$x=%%x"& set "$=!$!!$x:~-3!"
  if not "!$b!"=="000000000000" if not defined $$!$! if not defined $_!$b! (
    set $_!$b!=.& set "$$!$!=!$a! !$b!"))
::вывод в файл
(echo:IP Машины       Мак адрес& echo:
 for /f "tokens=1* delims==" %%x in ('set $$') do echo %%y
)>"%LOG%"