[FlatX007]

А консольные команды ни кто не отменял

REG COPY /? - справка по команде.

[Creat0R]

Расширенная библиотека для работы с реестром

Пример с её использованием:

Код:

#include <Array.au3>
#include <Registry_UDF.au3>

$aArr = _RegEnumKeys2Array("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run")

For $i = 1 To $aArr[0][0]
    $sPath = StringRegExpReplace($aArr[$i][0], "\\Run\\", "\\Run_Test\\") ;Копируем в Run_Test
    $sPath = StringRegExpReplace($sPath, "\\[^\\]*$", "")
    $sKey = StringRegExpReplace($aArr[$i][0], "^.*\\", "")
    $sKey = StringReplace($sKey, "!", "! ") ;этот символ на конце почему то блокирует запись

    $sRet = RegWrite($sPath, $sKey, $aArr[$i][2], $aArr[$i][1])
Next

[amel27]

может вместо копирования создать символическую ссылку на нужный ключ реестра?

[crashtuak]

Creat0R, спасибо, ваш вариант работает идеально.

[Yashied]

IMHO так быстрее и надежнее.

Код:

Global Const $HKEY_LOCAL_MACHINE = 0x80000002


$hKey = _WinAPI_RegCreateKey($HKEY_LOCAL_MACHINE, 'SOFTWARE\Wow6432Node\Diskeeper Corporation')
_WinAPI_RegCopyTree($HKEY_LOCAL_MACHINE, 'SOFTWARE\Diskeeper Corporation', $hKey)
_WinAPI_RegCloseKey($hKey)

Func _WinAPI_RegCloseKey($hKey)

    Local $Ret = DllCall('advapi32.dll', 'long', 'RegCloseKey', 'ulong_ptr', $hKey)

    If @error Then
        Return SetError(1, 0, 0)
    Else
        If $Ret[0] Then
            Return SetError(1, $Ret[0], 0)
        EndIf
    EndIf
    Return 1
EndFunc   ;==>_WinAPI_RegCloseKey

Func _WinAPI_RegCopyTree($hSrcKey, $sSrcSubKey, $hDestKey)

    Local $Ret = DllCall('shlwapi.dll', 'long', 'SHCopyKeyW', 'ulong_ptr', $hSrcKey, 'wstr', $sSrcSubKey, 'ulong_ptr', $hDestKey, 'dword', 0)

    If @error Then
        Return SetError(1, 0, 0)
    Else
        If $Ret[0] Then
            Return SetError(1, $Ret[0], 0)
        EndIf
    EndIf
    Return 1
EndFunc   ;==>_WinAPI_RegCopyTree

Func _WinAPI_RegCreateKey($hKey, $sSubKey = '', $iDesired = 0xF003F, $iOptions = 0, $tSecurity = 0)

    Local $Ret = DllCall('advapi32.dll', 'long', 'RegCreateKeyExW', 'ulong_ptr', $hKey, 'wstr', $sSubKey, 'dword', 0, 'ptr', 0, 'dword', $iOptions, 'dword', $iDesired, 'ptr', DllStructGetPtr($tSecurity), 'ulong_ptr*', 0, 'dword*', 0)

    If @error Then
        Return SetError(1, 0, 0)
    Else
        If $Ret[0] Then
            Return SetError(1, $Ret[0], 0)
        EndIf
    EndIf
    Return SetError(0, Number($Ret[9] = 1), $Ret[8])
EndFunc   ;==>_WinAPI_RegCreateKey

[semiono]

Тут важно чтобы приложения были 64-битными, иначе некорректно может отображаться реестр.