[kotkovets]

wolkow70,
X:\Windows\SysWOW64\regedit.exe - это же $SYSDIR\regedit.exe c редиректом в x64 ${EnableX64FSRedirection}

[wolkow70]

Что-то я запутался совсем.

Так не работает.
execwait '$windir\SysWOW64\regedit.exe /s "$EXEDIR\reg.reg"'

Так не работает.
${EnableX64FSRedirection}
execwait '$windir\regedit.exe /s "$EXEDIR\reg.reg"'

Получается, что нужно так?
${EnableX64FSRedirection}
execwait '$windir\SysWOW64\regedit.exe /s "$EXEDIR\reg.reg"'

[Lisabon]

wolkow70,

Код:

!include "MUI2.nsh"
!include "x64.nsh"
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "Russian"
OutFile Test.exe
ShowInstDetails show
 
Section
${If} ${RunningX64} 
  ; в 32-х битный реестр
          ${EnableX64FSRedirection}
		  execwait '$windir\regedit.exe /s "$EXEDIR\reg.reg"'
          MessageBox MB_OK "Enable) $windir\regedit.exe"
  ; в 64-х битный реестр
          ${DisableX64FSRedirection}
		  execwait '$windir\regedit.exe /s "$EXEDIR\reg.reg"'
          MessageBox MB_OK "Disable) $windir\regedit.exe"
 ${EndIf}
SectionEnd

[wolkow70]

Section ${If} ${RunningX64} ; в 32-х битный реестр ${EnableX64FSRedirection} execwait '$windir\regedit.exe /s "$EXEDIR\reg.reg"' MessageBox MB_OK "Enable) $windir\regedit.exe" ; в 64-х битный реестр ${DisableX64FSRedirection} execwait '$windir\regedit.exe /s "$EXEDIR\reg.reg"' MessageBox MB_OK "Disable) $windir\regedit.exe" ${EndIf} SectionEnd »

Да, так работает. Мне нужно было поменять местами ${EnableX64FSRedirection} и ${DisableX64FSRedirection}. Я исходил из разрядности установщика и думал, что EnableX64FSRedirection подключает 64-битный реестр. Оказалось, что наоборот и исходить нужно было из разрядности системы. Всем спасибо.

[wolkow70]

kotkovets, добрый день.

Пытаюсь разобраться в вопросе определения ключей реестра

Нашел в справке вот что:

${If} ${KeyExists} "${HKCU}\Software\7-zip"
# здесь выполняются команды, если ключ существует
DetailPrint "Ключ есть!"
${Else}
# здесь выполняются команды, если ключа не существует
DetailPrint "Ключа не существует!"
${EndIf}

Но это не вовсем то, что требуется.

Пытаюсь сделать обновленный более гибкий макрос файловых ассоциаций

Алгоритм нужен такой:

1. Если существует ключ;
2. И если не присвоено значение по умолчанию;
3. Или значение имеет нулевую длину
- то переход бо безусловной метке.
Иначе выполняются комманды бэкапа и перезаписи асооциаций.

У самого получилось пока вот что:

Код:

!macro RegisterExtension extenstion
Push $1
Push $2	
;
StrCpy $ClassName "Winamp.File.${extenstion}"
;
ReadRegStr $1 HKCU "Software\Classes\.${extenstion}" ""    ; Читаем сначала в HKCU
StrCmp "$1" "" NoAssocHKCU        ;если значение по умолчанию не присвоено не пишем ассоциацию в HKCU 
StrCmp "$1" "$ClassName" NoBackupHKCU   ;если совпадает тип файла не бэкапим
WriteRegStr HKCU "Software\Classes\.${extenstion}" "Winamp_Back" "$1" ;иначе бэкапим

NoBackupHKCU:

WriteRegStr HKCU "Software\Classes\.${extenstion}" "" "$ClassName"  ;пишем ассоциацию

NoAssocHKCU:
;
ReadRegStr $1 HKCU "Software\Classes\.${extenstion}" ""   ; заново читаем значение в HKCU 
StrCmp "$1" "$ClassName" NoAssocHKLM     ;если применена ассоциация в HKCU пропускаем переход в HKLM
;
DeleteRegValue HKCU "Software\Classes\.${extenstion}" ""   ; удаляем значение пустого ключа в HKCU  на случай нулевой длины (бывает например в ключах созданных AIMP) 
;
ReadRegStr $2 HKLM "SOFTWARE\Classes\.${extenstion}" ""  ;читаем значение в HKLM 
StrCmp "$2" "" NoBackupHKLM                            ;если нет значения по умолчанию не бэкапим
StrCmp "$2" "$ClassName" NoBackupHKLM        ;если тип совпадает - не бэкапим
WriteRegStr HKLM "SOFTWARE\Classes\.${extenstion}" "Winamp_Back" "$2" ;иначе бэкапим

NoBackupHKLM:

WriteRegStr HKLM "SOFTWARE\Classes\.${extenstion}" "" "$ClassName" ;пишем ассоциацию 

NoAssocHKLM:

Pop $1
Pop $2
!macroend

Тут смысл повторить логику внесения асооциаций оригинального Winamp. Если есть значение по умолчанию в HKCU , то ассоциация пишется и бэкапится в HKCU, если ассоциация в HKCU не прописана, то вносится и бэкапится в HKLM. В принципе так и должно быть в нормальной программе.

[diakov]

kotkovets, а как включить orange.bmp в сам exe шник что бы на другом компе работало

Код:

!include "MUI2.nsh"
outfile file.exe
page custom pagevelcom
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "Russian"

var dlg
var btn

Function pagevelcom
  nsDialogs::create 1018
  pop $dlg
  ${NSD_CreateButton} 120u 120u 180u 20u "Краткая информация об этом скрипте"
  pop $btn
  ${NSD_OnClick} $btn ClickButton
  nsDialogs::show
FunctionEnd

Function ClickButton
  pop $btn
  ExecShell open "${NSISDIR}\Contrib\Graphics\Wizard\orange.bmp"
FunctionEnd

Section
SectionEnd

[kotkovets]

что бы на другом компе работало »

Код:

Function ClickButton
  pop $btn
  InitPluginsDir
  File "/oname=$PLUGINSDIR\image.bmp" "Абсолютный(относительный)_путь_к_картинке\***.bmp"
  ExecShell open "$PLUGINSDIR\image.bmp"
FunctionEnd

[Olef2387]

Здравствуйте.
Подскажите, Как в нсис убрать кнопку "детали" при установке?

[kotkovets]

Подскажите, Как в нсис убрать кнопку "детали" при установке? »

4.8.1.34 ShowInstDetails
hide|show|nevershow
---
В начале скрипта вне секции или функции:

Код:

ShowInstDetails nevershow

[Olef2387]

kotkovets. Вот это оперативность. Огромное спасибо.