Показать полную графическую версию : [решено] Как сделать,что б батник проверял число ?
Нужно что б батник проверял больше сейчас определенной даты или нет.
Тут я вижу несколько проблем :
1 незнаю как вообше дату проверить
2 не знаю как определить больше сейчас орпределенной даты или нет.
Ведь число может быть и меньше,а месяц следующий,или даже год
Ничего сложного нет:
@echo off
if /i '%date%' GTR '12.11.2006' goto 2
echo меньше
goto end
:2
echo больше
:end
pause
exit
Ессно, число надо задавать руками, в формате, установленном системой.
mitiya
в дополнение к ShaddyR - как присвоить значение текущей даты переменной date:For /F "Tokens=1* Delims= " %%i In ('Date /T') DO Set date=%%i
P.S. Параметры локализации можно взять из реестра - iDate и sDate ветки "HKCU\Control Panel\International"
amel27: а зачем это может пригодиться? Честно - вообще не понял смысла... date и так содержит текущую дату... собсно, она не переменная, а внутренняя команда дос..
Нука корифеи винШелла - как красиво взять дату у файла или директории? Ну потом соотв их запихнуть в переменной для сравнения.
А как взять дату установки винди?
ShaddyR
этот код правда выдает что сейчас меньше 12.09.2006 ,а сейчас равно 12.09.2006 :-)
но все понятно.
Спасибо.
ShaddyR
чтобы зная разделитель и порядок парсить строку независимо от локали
NikLokIf Exist %file% For %%i In (%file%) Do SET TIMESTAMP=%%~tiдля директории аналогично, ессно с указанием пути
nj_
можно таким же порядком - по дате файла %SYSTEMROOT%\setupact.log
mitiya: Ну, главное ведь - идея, остальное нарастет ;). ю а велкам. (с) Timsky
(Используй оператор сравнения GEQ вместо GTR, будет равно) )
можно таким же порядком - по дате файла %SYSTEMROOT%\setupact.а как дату файла витенуть?
nj_: озвучу, раз аналогия не понята ;)
set file=%SYSTEMROOT%\setupact.log
If Exist %file% For %%i In (%file%) Do SET TIMESTAMP=%%~ti
echo %timestamp%
Провтикал аналогию :sorry:
Спасибо!
Ешо один глупий вопрос:
как присвоит переменной значение дати на n дней (месяцев) больше (меньше) текущей?
nj_как присвоит переменной значение дати на n дней (месяцев) больше (меньше) текущей?
я честно попытался решить этот вопрос... с учетом отсутствия в коммандном процессоре мат. операций. Все, что я нашел - это вот эта лабораторная работа (http://moldovan.hotmail.ru/docs/Lab2.rtf), в которой среди прочего делается
Написание командного скрипта для вывода ряда фибоначи (т.е. где каждый последующий член ряда равен сумме двух предыдущих: 1, 1, 2, 3, 5, 8, 13, ...). Для этого будет использовано несколько пакетных файлов, работа с переменными окружения и тд.
Пару раз его перечитал и понял, шо я ничего не понял. Попробуй, мож у тебя лучше получится ;)
DarkTiger
18-10-2006, 15:39
Эммммм ребят, сори за офтоп, кто нибудь может поделиться своими источниками (будь то название книги, сылка на электронное издание, какие то статьи в инете и пр.) по написанию bat файлов. А то через поисковик ничего дельного не нашёл. Заранее спасибо за ответ
Sanja Alone
18-10-2006, 16:14
DarkTiger
поделиться своими источниками
Когда-то давно учился этому делу по книге Питера Нортона "MS-DOS" (точного названия не помню; помню, что в мягкой зеленой обложке была). Недавно обновил знания просто почитав C:\WINDOWS\Help\ntcmds.chm :)
ShaddyRс учетом отсутствия в коммандном процессоре мат. операций.
ты не прав - все календарные расчеты основаны на целочисленной арифметике, так что возможностей командного процессора за глаза хватает, хотя алгоритмы действительно нельзя назвать простыми - в языках высокого уровня они скрыты за функциями преобразования времени. Как-то хотел сделать расчет одной похожей задачки на CMD, но время поджимало и пришлось делать на VBS... если соберусь, то попробую переделать...
DarkTiger
из "избранного":
http://www.windowsfaq.ru/content/category/3/7/45
http://www.windowsfaq.ru/content/category/3/19/57/
http://www.microsoft.com/technet/prodtechnol/Windows2000serv/support/FAQW2KCP.mspx
http://www.robvanderwoude.com/index.html :up:
DarkTiger
19-10-2006, 18:30
amel27 Огромное спасибо, уже читаю, написано на доступном языке, кроме последних 2 сылок, потому как англиский знаю плохо :(
как присвоит переменной значение дати на n дней (месяцев) больше (меньше) текущей? Самый простой способ (и самый медленный) - итеративный цикл по количеству дней... Как и предупреждал, несколькими строчками кода не обошлось. Для ускорения расчетов можно было применить цикл по месяцам с выравниванием даты на последнем шаге, но тогда код стал бы еще более громоздким и плохо читаемым.
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
Rem Параметры расчета: кол-во дней (>0!) и направление (+/-)
SET DAYS=730
SET SIGN=+
Rem Установка окружения и цикл расчета
CALL :GetDate
CALL :GetMnthDays
:Start
CALL :NextDay "%SIGN%1"
SET /A DAYS=%DAYS%-1
IF %DAYS% NEQ 0 GOTO :Start
Rem Вывод результата и завершение работы
CALL :ShowDate
EXIT
Rem Перемещение на следующий/предыдущий календарный день
:NextDay
SET /A Day=%Day%%~1
IF %Day% GTR !DOFW! (
CALL :NextMonth +1
CALL :GetMnthDays
SET /A Day=1
)
IF %Day% EQU 0 (
CALL :NextMonth -1
CALL :GetMnthDays
SET /A Day=!DOFW!
)
GOTO :EOF
Rem Расчет года и месяца, отстоящих от заданного
:NextMonth
SET /A MNDF=%Year%*12+%Month%%1
SET /A Year=(%MNDF%-1)/12
SET /A Month=%MNDF%-%Year%*12
GOTO :EOF
Rem Число дней в заданном месяце
:GetMnthDays
IF %Month% EQU 2 (
CALL :IsYearVisok
SET /A DOFW = 28+!VISOK!
) ELSE (
SET NUM=0
FOR %%i IN (31 28 31 30 31 30 31 31 30 31 30 31) DO (
SET /A NUM=!NUM!+1
IF %Month% EQU !NUM! (
SET DOFW=%%i
GOTO :EOF
)
)
)
GOTO :EOF
Rem Проверка года на високосность
:IsYearVisok
SET /A M1=%Year%-(%Year%/4)*4
SET /A M2=%Year%-(%Year%/100)*100
SET /A M3=%Year%-(%Year%/400)*400
SET VISOK=0
IF 0 EQU %M1% IF 0 NEQ %M2% SET VISOK=1
IF 0 EQU %M3% SET VISOK=1
GOTO :EOF
Rem Чтение текущей даты в переменные окружения
:GetDate
FOR /F "tokens=1,3" %%i IN ('REG QUERY "HKCU\Control Panel\International" /s^|findstr /C:"iDate" /C:"sDate"') DO SET %%i=%%j
FOR /F "TOKENS=1-4* DELIMS=%sDate% " %%A IN ('DATE/T') DO (
IF %iDate%==0 (
SET Year=%%C
SET Month=%%A
SET Day=%%B
)
IF %iDate%==1 (
SET Year=%%C
SET Month=%%B
SET Day=%%A
)
IF %iDate%==2 (
SET Year=%%A
SET Month=%%B
SET Day=%%C
)
)
GOTO :EOF
Rem Отображение итоговой даты
:ShowDate
SET Month=0%Month%
SET Month=%Month:~-2%
SET Day=0%Day%
SET Day=%Day:~-2%
IF %iDate%==0 ECHO %Month%%sDate%%Day%%sDate%%Year%
IF %iDate%==1 ECHO %Day%%sDate%%Month%%sDate%%Year%
IF %iDate%==2 ECHO %Year%%sDate%%Month%%sDate%%Day%
GOTO :EOF
Sanja Alone
11-07-2007, 11:50
Немного дополнил ф-цию получения текущей даты из поста 18 (http://forum.oszone.net/post-500342-18.html). Дополнение связано с различием в отображении даты в зависимости от sLongDate и sShortDate. Я обошелся без необходимости проверки этих параметров в реестре, а поступил проще (правда, понадобилась лишняя переменная).
Rem Чтение текущей даты в переменные окружения
:GetDate
for /f "tokens=1,3" %%j in ('reg query "HKCU\Control Panel\International" /s^|findstr /C:"iDate" /C:"sDate"') do set %%j=%%k
for /f %%j in ('echo %date%^|find " " /C') do (
if %%j == 1 (
for /f "tokens=2 delims= " %%j in ('echo %date%') do set mdate=%%j
) else (
set mdate=%date%
)
)
for /f "tokens=1,2,3 delims=%sDate%" %%j in ('echo %mdate%') do (
if %iDate%==0 (
set Month=%%j
set Day=%%k
set Year=%%l
)
if %iDate%==1 (
set Day=%%j
set Month=%%k
set Year=%%l
)
if %iDate%==2 (
set Year=%%j
set Month=%%k
set Day=%%l
)
)
goto :EOF
Да, совсем забыл. Вот ф-ция для установки даты:
Rem Установка даты
:SetDate
if %iDate%==0 (
date %Month%%sDate%%Day%%sDate%%Year%
) else (
if %iDate%==1 (
date %Day%%sDate%%Month%%sDate%%Year%
) else (
if %iDate%==2 (
date %Year%%sDate%%Month%%sDate%%Day%
)
)
)
goto :EOF
Ситуация, в к-рой могут пригодиться приведенные выше ф-ции:
Rem Определение текущей даты
call :GetDate
Rem прибавление 1 года к дате
set /a Year+=1
Rem Установка даты
call :SetDate
Rem Выполнение определенных манипуляций
Rem Возврат реальной даты (отнимаем 1 год)
set /a Year-=1
Rem Установка даты
call :SetDate
© OSzone.net 2001-2012
vBulletin v3.6.4, Copyright ©2000-2025, Jelsoft Enterprises Ltd.