bat фаил для удаления определённого файла по заданному пути

[beowulf0208]

Здравствуйте. Есть необходимость удалить логины и пароли на компьютере из браузера Mozilla Firefox. На мой взгляд самый простой способ это сделать это удалить файлы, которых хранятся логины и пароли, т.е. файлы key3.bd (key4.bd) и logins.json. Проблема в том, что эти файлы на разных компьютерах и в разных учётных записяъ хранятся в разных папках профелей Firefox, т.е. начало пути одинаковое (%APPDATA%\Mozilla\Firefox\Profiles), а окончание (название профелей) разное.
Как сделать bat фаил, который по пути %APPDATA%\Mozilla\Firefox\Profiles и во всех вложенных папках найдёт и удалит все файлы key3.bd (key4.bd) и logins.json ?
Что-то типа del /f /s /q %APPDATA%\Mozilla\Firefox\Profiles\*:\key3.bd,%APPDATA%\Mozilla\Firefox\Profiles\*:\key4.bd,%APPDATA %\Mozilla\Firefox\Profiles\*:\logins.json

[DJ Mogarych]

Powershell

dir $env:appdata\Mozilla\Firefox\Profiles -Recurse -Include "key*.bd","logins.json" |del -WhatIf

Чтобы реально удаляло, уберите -WhatIf.

[megaloman]

@Echo Off &cls
Set "Profiles=%APPDATA%\Mozilla\Firefox\Profiles"
Set Files="key3.db" "key4.db" "logins.json"

Pushd "%Profiles%" ||(Echo !!! Folder "%Profiles%" not found &Pause &Exit /B 2)
For /F "usebackq delims=" %%f In (`2^>nul Dir /S /B /A:-D %Files%`) Do Echo Del "%%f"
Popd
Pause
Exit /B
Здесь в названиях файлов возможны групповые символы, например "key*.db"
Для реального удаления уберите Echo

Либо так:@Echo Off &cls
Set "Profiles=%APPDATA%\Mozilla\Firefox\Profiles"
Set Files="key3.db" "key4.db" "logins.json"

For %%f In (%Files%) Do 2>nul Del /S "%Profiles%\%%f"
Pause
Exit /B
Здесь в названиях файлов групповые символы не работают.
Уточните расширение: не .bd а .db