Показать полную графическую версию : [решено] Перемещение и переименование файлов
megaloman
12-01-2018, 16:23
DJ Mogarych, it3,тогда можно файлы переименовывать по дате создания перед копированием »Файлы изначально именуются с датой создания как гггг-мм-дд_(хххх).tif, тут уже не за чем напрягаться. Что касается времени создания, Я рассматривал этот вариант, но, увы, в CMD выдернуть время создания файла хотя бы с секундами я не умею, а делать какой-нибудь костыль - при большом количестве файлов это резко замедлит работу. @Echo Off
cls
Set "BoxIn=Z:\Box_In\NaklScan"
Set "BoxOut=Z:\Box_In\NaklScan5"
Set "Mask=20??-??-??_(*).tif"
If Not Exist "%BoxOut%" Md "%BoxOut%"
FOR /F "usebackq tokens=1,2* delims=()" %%i IN (`2^>nul Dir "%BoxIn%\%Mask%" /A:-D /B /O:D /T:C`) DO Call :Transfer "%%i" "%%k" "%BoxIn%\%%i(%%j)%%k"
Pause
GoTo :Eof
:Transfer
Set "Ftime=%~t3"
Set "Ftime=%Ftime:~-5%"
Set "Ftime=%Ftime::=%"
Set "Ftime=%Ftime: =0%"
Set /A ND=1
Set "NewFile=%BoxOut%\%~1%Ftime%%~2"
:Begin
If Not Exist "%NewFile%" (
Move %3 "%NewFile%" >nul
GoTo :Eof
)
Set /A ND+=1
Set "NewFile=%BoxOut%\%~1%Ftime%-%ND%%~2"
GoTo :Begin
GoTo :Eof
Формат имен перемещенных файлов при этом
гггг-мм-дд_ччми.tif
Если за одну минуту создадутся несколько файлов, то имена будут иметь вид:
гггг-мм-дд_ччми.tif
гггг-мм-дд_ччми-2.tif
гггг-мм-дд_ччми-3.tif и т д.
Доброго времени суток всем!
Есть необходимость перемещать файлы:
"2018-01-18.tif",
"2018-01-18_(1).tif",
"2018-01-18_(2).tif",
"2018-01-18_(3).tif",
"2018-01-18_(4).tif",
"2018-01-18_(5).tif",
"2018-01-18_(6).tif",
"2018-01-18_(7).tif",
"2018-01-18_(8).tif",
"2018-01-18_(9).tif",
"2018-01-18_(10).tif",
"2018-01-18_(11).tif",
"2018-01-18_(12).tif",
"2018-01-18_(13).tif",
"2018-01-18_(14).tif",
... ... ... ... ... ... ... ... ...
"2018-01-18_(7000).tif",
"2018-01-18_(7001).tif",
"2018-01-18_(7002).tif",
"2018-01-18_(7003).tif",
"2018-01-18_(7004).tif",
... ... ... ... ... ... ... ... ...
Но таким образом, чтобы переместились все файлы, кроме последнего. Т.е. эти переместились:
"2018-01-18.tif",
"2018-01-18_(1).tif",
"2018-01-18_(2).tif",
"2018-01-18_(3).tif",
"2018-01-18_(4).tif",
"2018-01-18_(5).tif",
"2018-01-18_(6).tif",
"2018-01-18_(7).tif",
"2018-01-18_(8).tif",
"2018-01-18_(9).tif",
"2018-01-18_(10).tif",
"2018-01-18_(11).tif",
"2018-01-18_(12).tif",
"2018-01-18_(13).tif",
"2018-01-18_(14).tif",
... ... ... ... ... ... ... ... ...
"2018-01-18_(7000).tif",
"2018-01-18_(7001).tif",
"2018-01-18_(7002).tif",
"2018-01-18_(7003).tif",
А этот остался:
"2018-01-18_(7004).tif".
Подскажите пожалуйста, как реализовать?
it3, плохо что у вас имена файлов не структурированы, и при простом анализе файл, например, "2018-01-18_(6).tif", будет идти после файлов с "2018-01-18_(5000).tif" по "2018-01-18_(5999).tif".
it3, плохо что у вас имена файлов не структурированы, и при простом анализе файл, например, "2018-01-18_(6).tif", будет идти после файлов с "2018-01-18_(5000).tif" по "2018-01-18_(5999).tif". »Можно ведь переносить по времени создания. Т.е. нужно проанализировать содержимое папки и перенести наиболее ранние файлы, а более поздние оставить.
Так ведь?
Можно ведь переносить по времени создания »
Можно и так — и будет быстрее; поскольку хоть и можно организовать перевод величин в скобках из текстового в числовое представление — дальнейший анализ всё равно будет сложнее.
А здесь можно организовать цикл:
Проверяем два последовательных файла (причём что это за файлы — всё равно). Если второго файла нет — завершаем работу: задача выполнена.
Если есть — сравниваем даты, более старый перемещаем и идём в начало цикла.
Впрочем, если переводить текст в скобках в числа — можно делать практически точно так же, сравнивая преобразованные имена.
megaloman
09-06-2018, 11:19
it3, Можно ведь переносить по времени создания. »Проще пареной репы@Echo Off
Set "BoxIn=Z:\Box_In"
Set "BoxOut=Z:\Box_Out"
Set "Mask=2018-01-18*.tif"
FOR /F "usebackq skip=1 delims=" %%f IN (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:-D /O:-D /T:C`) DO >nul Move "%BoxIn%\%%f" "%BoxOut%\"
GoTo :Eof
Но подозреваю, начнётся уточнение и развитие постановки, и код надо будет пересаживать и выращивать.
Подскажите пожалуйста, как реализовать? »
Вопрос в том, как происходит отбор файлов. В смысле в каталоге присутствуют ещё *.tif, кроме перечисленных?
А так, с помощью powershell и ... ну да ладно, пока без лирики:
script.ps1
$src = 'c:\source'
$dst = 'c:\destination'
dir "$src\*" -inc "*.tif" -file|sort -prop @{
Expression={[int]($_.name -split "\(|\)")[1]}
} -desc|select -skip 1|%{mi $_.fullname $dst}
Исправил маску:
@Echo Off
Set "BoxIn=c:\Temp\Archive\"
Set "BoxOut=c:\Temp\Archive\1\"
Set "Mask=20??-??-??_(*).tif"
FOR /F "usebackq skip=1 delims=" %%f IN (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:-D /O:-D /T:C`) DO >nul Move "%BoxIn%\%%f" "%BoxOut%\"
GoTo :Eof
Но этот скрипт оставляет в папке "c:\Temp\Archive\" один файл, который был создан раньше всех, а должно быть наоборот. Должен оставаться файл, который был создан позже всех.
Скриншоты во вложении.
Вопрос в том, как происходит отбор файлов. В смысле в каталоге присутствуют ещё *.tif, кроме перечисленных?
»
Нет.
Скрипт работает. Спасибо.
megaloman
09-06-2018, 12:34
it3, Подозреваю, Вы используете тестовую папку, в которую накопировали файлы. И в каком порядке они копировались (создавались при этом) - Вам лучше знать. Как и то, какое время на скриншотах отображено. Попробуйте скрипт с ключом не /T:C (по времени создания) а /T:W (по времени изменения).Set "Mask=20??-??-??_(*).tif" »При наличии в папке данных за много дней останется единственный самый последний файл за самый последний день.
Кроме того, останутся все файлы 20??-??-??.tif. Вас это устраивает?
Кроме того, останутся все файлы 20??-??-??.tif. Вас это устраивает? »Нет.
megaloman
09-06-2018, 18:32
it3, Что Вас не устраивает? Останутся все файлы 20??-??-??.tif? Или что останется единственный нумерованный файл?
it3, Если надо в каждой дате сохранить последний файл (отбор файла по каждой дате по времени последнего изменения)@Echo Off
Set "BoxIn=Z:\Box_In"
Set "BoxOut=Z:\Box_Out"
Set "Mask=20??-??-??*.tif"
Set "Dtt=0000-00-00"
FOR %%f IN ("%BoxIn%\%Mask%") DO Set Df=%%~nf &Call :LastFile "%%Df:~0,10%%" "%%~xf"
GoTo :Eof
:LastFile
If "%Dtt%"==%1 GoTo :Eof
Set "Dtt=%~1"
Set "MaskData=%BoxIn%\%Dtt%*%~2"
FOR /F "usebackq skip=1 delims=" %%f IN (`2^>nul Dir "%MaskData%" /B /A:-D /O:-D /T:W`) DO >nul Move "%BoxIn%\%%f" "%BoxOut%\"
GoTo :EofА если вообще не привязываться ко времени создания или изменения, а к номеру (но это медленнее)@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
Set "BoxIn=Z:\Box_In"
Set "BoxOut=Z:\Box_Out"
Set "Mask=20??-??-??*.tif"
Set "Dtt=0000-00-00"
FOR %%f IN ("%BoxIn%\%Mask%") DO Set Df=%%~nf &Call :LastFile "%%Df:~0,10%%" "%%~xf"
GoTo :Eof
:LastFile
If "%Dtt%"==%1 GoTo :Eof
Set "Dtt=%~1"
Set "MaskData=%BoxIn%\%Dtt%*%~2
Set /A Max=0
Set "NF=%~1%~2"
FOR /F "usebackq tokens=1,2* delims=()" %%i IN (`2^>nul Dir "%MaskData%" /B /A:-D /O:-N`) DO If Not "%%k"=="" If !Max! LSS %%j Call Set /A Max=%%j &Set "NF=%%i(%%j)%%k"
FOR %%i IN ("%MaskData%") DO If Not "%%~nxi"=="%NF%" Move /Y "%%i" "%BoxOut%\" >nul
GoTo :Eof
© OSzone.net 2001-2012
vBulletin v3.6.4, Copyright ©2000-2025, Jelsoft Enterprises Ltd.