Последовательное, циклическое переименование файлов в каталоге по кругу в cmd.

[Vasylich]

Здравствуйте!
Почти не разбираюсь в скриптах, поэтому прошу помощи.
В каталоге есть файлы c числовыми именами: 01.jpg, 02.jpg и т.д.
Нужно переименовывать файлы так, что бы после каждого срабатывания cmd
последний становился первым по порядку цифр, первый вторым, второй - третьим и т.д..
Первоначальное именование по порядку возможно, если будет необходимо для скрипта.
Файлов может быть от 01 до 99.

Спасибо.

[Foreigner]

@echo off
setlocal enabledelayedexpansion

for %%i in (*.jpg) do set /a cnt+=1
for %%i in (*.jpg) do (

set "new=0!cnt!"
ren "%%i" "!new:~-2!.tmp"
set /a cnt-=1

)

ren *.tmp *.jpg

[Iska]

Foreigner, а вдрух у него там FAT32!

[Foreigner]

Iska, А в чем может возникнуть проблема? Под рукой даже флешки нет проверить

[Elven]

Foreigner, в именах.

[alpap]

Vasylich, Переименуютя все сразу в нужном вам порядке с первого запуска:

@echo off
for /f "delims= eol=" %%a in ('dir /a-d/b "katalog\*.jpg"^|sort /+2147483647') do set /a n+=1& cmd/v/c set "m=0!n!"^& ren "katalog\%%~nxa" "new!m:~-2!%%~xa"
exit /b
.

при следующем запуске, по идее, должно произойти обратное, не проверял.

[Iska]

Iska, А в чем может возникнуть проблема? »
В порядке отдачи имён функциями ОС.

На NTFS будет всегда лексикографический, поскольку они так и хранятся в MFT — в виде упорядоченного B+ дерева. На FATx порядок будет соответствовать дате создания файлов:
H:\04>for /l %i in (5, -1, 1) do @copy nul 0%i.txt
Скопировано файлов: 1.
Скопировано файлов: 1.
Скопировано файлов: 1.
Скопировано файлов: 1.
Скопировано файлов: 1.

H:\04>for %i in (*.txt) do @echo %i
05.txt
04.txt
03.txt
02.txt
01.txt
Ровно то же будет и в WSH, и в PoSH, и в C/C++.

В частности, из-за этого пришлось специально учитывать такую возможность здесь: VBScript & CMD: разделение файла на фрагменты и их последующее слияние — Серый форум (http://forum.script-coding.com/viewtopic.php?id=2322). В первом варианте я не сообразил как побороть сие простым способом, и сделал поочерёдное «подклеивание» частей. Затем тутошний коллега Diamond навёл меня на мысль, что достаточно просто предварительно скопировать части в правильном порядке во временную папку, а затем уже смело использовать «copy /b name.ext.part????.bin name.ext» в этой временной папке — ОС будет уже гарантированно отдавать файлы команде copy в нужном порядке (кстати, только сейчас заметил, что описание там в самом скрипте не исправил :)).

[Foreigner]

Iska, Давно не сталкивался, даже ради интереса создал vhd на fat32 -- действительно сортировка от обратного, тогда лучше через dir + sort (надеюсь, что там не 95)))

@echo off
setlocal enabledelayedexpansion

for %%i in (*.jpg) do set /a cnt+=1
for /f %%i in ('dir /b *.jpg ^| sort') do (

set "new=0!cnt!"
ren "%%i" "!new:~-2!.tmp"
set /a cnt-=1

)

ren *.tmp *.jpg

[Iska]

Ну да, тут вполне подойдёт даже и обычный «dir /b /o:n …».

[Vasylich]

Код: Выделить весь код
@echo off
setlocal enabledelayedexpansion
for %%i in (*.jpg) do set /a cnt+=1
for %%i in (*.jpg) do (
set "new=0!cnt!"
ren "%%i" "!new:~-2!.tmp"
set /a cnt-=1
)
ren *.tmp *.jpg »

Двойной прогон, правильно я понял?

[Foreigner]

Vasylich, Каждый запуск зеркально переименовывает файлы

[Vasylich]

Vasylich, Каждый запуск зеркально переименовывает файлы »
Зеркально не подойдет. Суть в том, чтобы после каждого срабатывания скрипта последний из списка файл становился 01.jpg, а 01.jpg - 02.jpg и т.д. Т.е. содержимое файлов сдвигалось на 1 по кругу.

[Vasylich]

А нельзя реализовать простую логику?
1. Находим 01 файл, сохраняем его копию.
2. Переименовываем в цикле пока не достигнет конца шаблон ??.jpg: 02->01, 03->02, 04->03 ... с шагом 1 до последний->предпоследний . Конец цикла.
3. Переименовываем сохранённый в шаге 1 в последний.
Всё.

[Foreigner]

@echo off
setlocal enabledelayedexpansion

for /f %%i in ('dir /b /on *.jpg') do set /a cnt=1%%~ni-100

ren 01.jpg 01.tmp

for /l %%i in (2,1,%cnt%) do (

set "old=0%%i"
set /a new=%%i-1
set "new=0!new!"

ren !old:~-2!.jpg !new:~-2!.jpg

)

set "cnt=0%cnt%"

ren 01.tmp %cnt:~-2%.jpg

[Vasylich]

Код: »
Получается нельзя в скрипте найти первый файл без перебора всего списка с помощью dir ?
По всей видимости в ФС файлы хранятся как попало и первый найденный не обязательно 01 и чтобы узнать, какой первый существующий в отсортированном списке нужно получить весь список и отсортировать его?

[Foreigner]

Получается нельзя в скрипте найти первый файл без перебора всего списка с помощью dir ? »
Можно. Но если прочтете выше по теме, то на FAT32 результат будет отличаться, поэтому надо сортировать. На NTFS файлы отсортируются сами (по длине строки и посимвольно). Просто попробуйте:

dir /b *.jpg

на NTFS и на FAT32

[Vasylich]

Просто попробуйте: »
Ну на fat32 пока негде попробовать. А там где будет использован скрипт - NTFS.

[Foreigner]

Тогда dir в данном случае не принципиален.

[Vasylich]

Тогда dir в данном случае не принципиален. »
Так а первый for все-равно весь список пройдет..

[megaloman]

@Echo off

Set "Where=Z:\kuku"
Set "Mask=*.jpg"

SetLocal EnableExtensions EnableDelayedExpansion
Set "Last=''"

for /f "usebackq delims=" %%i in (`dir "%Where%\%Mask%" /B /O:-N /A:-D 2^>nul`) Do (
Set "Name=%%i"
Set /A Num=1!Name:~0,2!+1
Set "Name=!Name:~2,9999!"
Ren "%Where%\%%i" "!Num:~1,2!!Name!"
If !Last!=='' Set Last=Ren "%Where%\!Num:~1,2!!Name!" "01!Name!"
)
!Last!
Имена файлов могут начинаться от 01 до 99 максимум. Dir c ключом /O:-N сортирует имена файлов по имени в обратном порядке от 99 до 01. Тупо переименовываем все файлы на имя с префиксом на 1 больше. При этом 99, если он был, переименуется в 00, что за пределами диапазона имён. Для самого первого в списке переименованного файла (со старым максимальным номером) запоминаем в переменную команду на переименование его в 01. По завершении цикла запускаем эту команду.
Маску, естественно, можно указать и ??.jpg
Хватает одного цикла и не делается никаких копий.