[решено] Как в фоновом режиме удалить Adobe Flash Player, Adobe Shockwave Player

[8ash8]

Добрый день, друзья есть необходимость написать скрипт производящий поиск всех установленных версий Adobe Flash Player, Adobe Shockwave Player и их удаление, а затем установкой на последнюю версию (из дистрибутива) все действия желательно производить в фоновом режиме.

[Elven]

Втихаря никак не получится. Для удаления флэша нужно закрытие всех браузеров и (почему-то) скайпа. Однако если это можно считать тихим то удалить можно приблизительно вот так:
качаем тулзу (https://helpx.adobe.com/flash-player/kb/uninstall-flash-player-windows.html)
пихаем ее туда куда надо (Гусары, молчать! Я имел ввиду нужный комп.)
убиваем все браузеры и скайп
taskkill.exe /f /im firefox.exe /im iexplore.exe /im chrome.exe /im opera.exe /im skype.exe
запускаем тулзу с ключом -uninstall
uninstall_flash_player.exe -uninstall

Что косается shockwave наверняка не скажу, у макромедиа был анынсталир (http://fpdownload.macromedia.com/get/shockwave/uninstall/win/sw_uninstaller.exe), но как он работает - не знаю.

[Iska]

и (почему-то) скайпа. »
Потому что Skype активно использует внутри себя и в интерфейсе IE в виде объекта WebBrowser.

[sov44]

Что косается shockwave »
Можно конечно утилитой, но в своём пакете WebFlashPack (http://forum.oszone.net/thread-312234.html) я его удаляю батником
@echo off
setlocal enabledelayedexpansion

for %%a in (System32 SysWOW64) do (
for %%b in ("%windir%\%%a\Adobe\Director\*") do (
echo %%b |>nul find /i "SwDir_" && regsvr32 /u /s "%%b"
echo %%b |>nul find /i "SWDNLD.EXE" && "%%b" /unregserver
)
for %%c in ("%windir%\%%a\Adobe\Shockwave 12\*") do (
echo %%c |>nul find /i "SwHelper" && "%%c" /unregserver
))

rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\System32\Adobe\Director"
rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\SysWOW64\Adobe\Director"
rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\System32\Adobe\Shockwave 12"
rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\SysWOW64\Adobe\Shockwave 12"
rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\System32\Macromed\Director"
rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\SysWOW64\Macromed\Director"
rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\System32\Macromed\Shockwave 10"
rundll32.exe advpack.dll,DelNodeRunDLL32 "%windir%\SysWOW64\Macromed\Shockwave 10"

Reg Delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Adobe Shockwave Player" /f
Reg Delete "HKLM\SOFTWARE\Macromedia\Shockwave 10" /f
Reg Delete "HKLM\SOFTWARE\Adobe\Shockwave 12" /f
Reg Delete "HKLM\SOFTWARE\MozillaPlugins\@adobe.com/ShockwavePlayer" /f
Reg Delete "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Adobe Shockwave Player" /f
Reg Delete "HKLM\SOFTWARE\Wow6432Node\Macromedia\Shockwave 10" /f
Reg Delete "HKLM\SOFTWARE\Wow6432Node\Adobe\Shockwave 12" /f
Reg Delete "HKLM\SOFTWARE\Wow6432Node\MozillaPlugins\@adobe.com/ShockwavePlayer" /f
del /f /a "%WinDir%\inf\SWFP.inf"

endlocal
exit /b