Определение модели ноутбука

[Valek271183]

Подскажите пожалуйста, в ветке реестра HKLM\HARDWARE\DESCRIPTION\System\BIOS\SystemProductName указана модель ноутбука K55V как сделать так что бы в зависимости от первой буквы модели переходить в нужную строчку, например если Модель N53 перейти на команду N, если X550 то перейти в строчку X и т.д.

[Iska]

Зачем «по первой букве», зачем не целиком?

Если в значении параметра нет пробелов, будет работать следующее:
@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq tokens=2*" %%i in (
`2^>nul reg.exe query "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v "SystemProductName" ^| find.exe /i "SystemProductName"`
) do set sSystemProductName=%%j

if defined sSystemProductName (
call :%sSystemProductName%
)

endlocal
exit /b 0

:K55V
echo K55V
exit /b 0

:N53
echo N53
exit /b 0

:X550
echo X550
exit /b 0

Если есть — надо будет несколько иначе сделать.

[Valek271183]

Iska, не работает, срабатывает если полностью совпадает модель, а нужно чтобы определялось только по первой букве модели

[Iska]

Valek271183, объясните, чем Вас не устраивает целиком? Для чего нужно:
нужно чтобы определялось только по первой букве модели »

[Valek271183]

Для установки фонового изображения

[NickM]

Valek271183, если только первый символ, тогда скорее определение серии ноутбука, а не конкретной модели.

[Foreigner]

> reg query HKLM\HARDWARE\DESCRIPTION\System\BIOS\SystemProductName
Ошибка: Не удается найти указанный раздел или параметр в реестре.



@echo off
setlocal

for /f "tokens=*" %%i in ('wmic computersystem get model /value') do 1>nul set "%%i"
if defined model (

if /i "%model:~0,1%"=="N" goto:N
if /i "%model:~0,1%"=="V" goto:V
if /i "%model:~0,1%"=="G" goto:G

)

echo model not recognized or not in list

goto:eof

:N
echo N
goto:eof

:V
echo V
goto:eof

:G
echo G