[решено] Как сделать запрос о введения слова

[ufooo]

Как в (.bat) скрипте сделать запрос о введения слова вместо символов: "*****" , и потом при нажатия клавиши, (Enter) сработал код с введенным словом.
Вот пример скрипта.
@Echo off
icacls "%Systemdrive%\PerfLogs\Admin" /grant *****:F
Exit /b

[Georgio]

@echo off

set/p "*****=*****="

cmd/v/c icacls "%SystemDrive%\PerfLogs\Admin" /grant !*****!:F

exit/b

[Iska]

Ручной ввод:
@echo off
setlocal enableextensions enabledelayedexpansion

set /p sName=Enter user name/account:

if defined sName (
icacls.exe "%Systemdrive%\PerfLogs\Admin" /grant %sName%:F
) else (
echo Not specified user name/account.
exit /b 1
)

endlocal
exit /b 0

С выбором из списка существующих неотключённых локальных аккаунтов:
@echo off
setlocal enableextensions enabledelayedexpansion

set /a iCount = 0
set sEntries=

for /f "usebackq skip=1 delims=" %%i in (
`wmic.exe UserAccount where "LocalAccount='True' AND Disabled='False'" get Name`
) do for /f %%j in ("%%~i") do (
set /a iCount += 1
set sEntries=!sEntries!!iCount!
set aName!iCount!=%%~j
echo !iCount!. %%~j
)

echo.

if exist "%SystemRoot%\System32\choice.exe" (
choice.exe /c "%sEntries%" /m "Select user name/account"
if errorlevel 1 set sChoice=!errorlevel!
) else (
set /p sChoice=Select user for change password [1-%iCount%]:
)

if defined sChoice if defined aName%sChoice% (
icacls.exe "%Systemdrive%\PerfLogs\Admin" /grant !aName%sChoice%!:F
) else (
echo Not specified user name/account.
exit /b 1
)

endlocal
exit /b 0