[решено] Подключение к сетевой папке другим пользователем

[~220V]

Всем здрасте!
Подскажите пжлст команду VBS скрипта для подключения к сетевой папке. Есть червер \\server\share\
в расшаренную папку share можно зайти только пользователем usr с паролем Pa$$w0rd

требуется выполнить некий аналог команды батфайлов net use \\server\share\ Pa$$w0rd /user:usr
чтоб следующая команда Set f = FSO.OpenTextFile("\\server\share\Log.txt", 8, True)
имела туда доступ.

Важное ЗЫ:
Диск мапить не оч приветствуется, так как у многих пользователей куча разных букв занята, искать свободную лень.

[Iska]

Option Explicit

Dim strShare
Dim strUserName
Dim strPassword

Dim strPath2File

Dim strFullPath2File


strShare = "\\Server\Share"
strUserName = "Server\UserName" ' или «Domain\UserName»
strPassword = "password"

strPath2File = "\001\0001.txt"


With WScript.CreateObject("WScript.Network")
.MapNetworkDrive "", strShare, False, strUserName, strPassword

With WScript.CreateObject("Scripting.FileSystemObject")
strFullPath2File = .BuildPath(strShare, strPath2File)

If .FileExists(strFullPath2File) Then
With .OpenTextFile(strFullPath2File)
WScript.Echo .ReadAll()
.Close
End With
Else
WScript.Echo "Can't find file [" & strFullPath2File & "]."
End If
End With

.RemoveNetworkDrive strShare
End With

WScript.Quit 0

[~220V]

Спасибо!

Исключил проверку, налабал по своему. Проверьте плз, сойдёть ли, вроде работает.


ServerShare = "\\Server\Share"
UserName = "DC\user"
Password = "123456"

Set NetworkObject = CreateObject("WScript.Network")
NetworkObject.MapNetworkDrive "", ServerShare, False, UserName, Password

Set FSO = CreateObject("Scripting.FileSystemObject")
Set f = FSO.OpenTextFile(ServerShare & "\Test.log", 8, True)

f.WriteLine Now

f.Close
NetworkObject.RemoveNetworkDrive ServerShare, True, False
скрипт записывает дату/время в файл расположенный в сетевой папке

[Iska]

Для того, чтобы сказать, сойдёт ли — надо знать глобальную цель/задачу.

P.S. Вы напрасно убрали «Option Explicit» и объявления переменных. Поверьте, обязательное использование этой инструкции сбережёт Вам немало сил и времени.