PDA

Показать полную графическую версию : Отправка письма


APiM
06-08-2014, 13:07
Подскажите скрипт на JS или VBS для отправки txt файла который лежит в папке Mail без ввода пароля от почты и не отправки самого txt, а его содержимого

Iska
06-08-2014, 20:40
для отправки txt файла »
Его имя?

APiM
06-08-2014, 23:44
Не самого txt, а его содержимого!

Iska
06-08-2014, 23:55
APiM, имя, имя у файла какое?

APiM
07-08-2014, 13:25
mail.txt

Iska
08-08-2014, 08:56
Пробуйте:
Option Explicit

Const cdoSendUsingPort = 2
Const cdoBasic = 1

Const strConstPartOfSchema = "http://schemas.microsoft.com/cdo/configuration/"


Dim strSourceFile
Dim strContent


strSourceFile = "c:\Mail\mail.txt"

With WScript.CreateObject("Scripting.FileSystemObject")
If .FileExists(strSourceFile) Then
With .OpenTextFile(strSourceFile)
strContent = .ReadAll()
.Close
End With

With WScript.CreateObject("CDO.Message")
.From = "account@mail.ru"
.To = "account@yandex.ru"
.Subject = "Content of file [" & strSourceFile & "]"

.TextBody = strContent
.TextBodyPart.Charset = "windows-1251"

With .Configuration.Fields
.Item(strConstPartOfSchema & "smtpserver") = "smtp.mail.ru"
.Item(strConstPartOfSchema & "sendusing") = cdoSendUsingPort
.Item(strConstPartOfSchema & "smtpserverport") = 25
.Item(strConstPartOfSchema & "smtpauthenticate") = cdoBasic
.Item(strConstPartOfSchema & "sendusername") = "account@mail.ru"
.Item(strConstPartOfSchema & "sendpassword") = "password"

.Update
End With

.Send
End With
Else
WScript.Echo "Source file [" & strSourceFile & "] not found."
WScript.Quit 1
End If
End With

WScript.Quit 0

P.S. Вложением — надёжнее: заведомо нет проблем с кодировкой.

APiM
08-08-2014, 10:25
Спасибо, а можно ещё сделать чтобы не надо было пароль вводить?

Iska
08-08-2014, 10:39
А это:
.Item(strConstPartOfSchema & "sendpassword") = "password"
что тогда?!

APiM
08-08-2014, 13:11
Можно как то сделать чтобы не нужно было вводить пароль от почты, просто скрипт будет использоваться не только мной, поэтому кто нибудь сможет посмотреть пароль

Iska
08-08-2014, 13:33
Можно как то сделать чтобы не нужно было вводить пароль от почты »
Нет, нельзя. Любые варианты «как-то» позволят получить этот пароль «не только Вам».

А что мешает завести для «не только Вы» свою учётную запись электронной почты, и пользовать её?




© OSzone.net 2001-2012