BAT поиск текста в файле с условием

[rosalin]

Помогите с батничком
Необходимо чтобы батник проверял в папке все файлы которые там есть.
Файлы по сути текстовые, но лежат в формате *.msg
так вот нужно чтобы батник проверял присутствует в файле текст например "for <adm@" , если да , то этот файл нужно скопировать в папку adm если "for <info@" то этот файл нужно скопировать в папку info.
Но важно поиск с начала файла и по первой найденной строке потому как в файле могут быть обе строки "for <adm@" и "for <info@" важна именно первая найденная строка

Заранее премного благодарен!

[Georgio]

Как-то так:

@echo off
for %%i in (*.msg) do (
for /f "delims=" %%j in ('
findstr /iln /c:"for <adm@" /c:"for <info@" "%%~i"^| findstr /b 1:
') do (
echo "%%j"| >nul (findstr /ilc:"for <adm@"&& copy "%%~i" "adm"|| copy "%%~i" "info")
)
)
exit /b

.

[rosalin]

Да скрипт работает, но как быть если нужно добавить больше аргументов, например искать "for <adm@" "for <info@" "for <ivanov@" "for <petrov@" "for <sidorov@" что первое находит в ту папку и кладем adm info ivanov petrov и т.д.

[Georgio]

Да не вопрос!


что первое находит в ту папку и кладем »

Если такой папки не существует, то она будет создана.


Полная сортировка по заданному алгоритму:

@echo off
setlocal enabledelayedexpansion
for %%i in (*.msg) do (
for /f "delims=" %%j in ('
findstr /inrc:"for <.*@" "%%~i"^| findstr /b 1:
') do (
set "string=%%j"
set "string=!string:*for <=!"
for /f "delims=@" %%k in ("!string!") do (
md "%%k" 2>nul
copy "%%~i" "%%k">nul
)
)
)
endlocal
exit /b

.

[Georgio]

как быть если нужно добавить больше аргументов, например искать "for <adm@" "for <info@" "for <ivanov@" "for <petrov@" "for <sidorov@" »



Еспи нужна выборочная сортировка с любым числом аргументов, то тогда так:

@echo off
call:# "adm" "info" "ivanov" "petrov" "sidorov"
exit /b

:#
for %%i in (*.msg) do (
for /f "delims=" %%j in ('
findstr /inrc:"for <.*@" "%%~i"^| findstr /b 1:
') do (
for %%k in (%*) do call:## "%%j" %%k "%%~i"
)
)
exit /b

:##
echo %1| >nul (
findstr /ilc:"for <%~2@"&& (
md %2 2>&1
copy %3 %2
))
exit /b

.

Если нужные папки не существуют, то они будут созданы.

[rosalin]

Ребята протестил на реальном файле не сработало

вот структурка

Return-path: <adm@domain.ru>
Received: from SERVER1C bydomain.ru ()
with ESMTP id 60-md50000009510.msg
for <adm@

структура как есть с пробелами

[rosalin]

не срабатывает если перед искомой строкой есть любой текст или просто несколько пустых строк

[Georgio]

rosalin, нашёл и устранил проблему. Привожу отредактированный код для обоих пакетных файлов.

@echo off
setlocal enabledelayedexpansion
for %%i in (*.msg) do (
for /f "delims=" %%j in ('
findstr /irc:"for <.*@" "%%~i"^| findstr /n "^"^| findstr /b 1:
') do (
set "string=%%j"
set "string=!string:*for <=!"
for /f "delims=@" %%k in ("!string!") do (
md "%%k" 2>nul
copy "%%~i" "%%k">nul
)
)
)
endlocal
exit /b

@echo off
call:# "adm" "info" "ivanov" "petrov" "sidorov"
exit /b

:#
for %%i in (*.msg) do (
for /f "delims=" %%j in ('
findstr /irc:"for <.*@" "%%~i"^| findstr /n "^"^| findstr /b 1:
') do (
for %%k in (%*) do call:## "%%j" %%k "%%~i"
)
)
exit /b

:##
echo %1| >nul (
findstr /ilc:"for <%~2@"&& (
md %2 2>&1
copy %3 %2
))
exit /b

[rosalin]

Georgio , круто! А как второй скрипт надо запускать с параметром ?

[Georgio]

А как второй скрипт надо запускать с параметром ? »


С помощью командной строки или запускающего пакетного файла: "somename.bat" "adm" "info" "ivanov" "petrov" "sidorov", предварительно убрав из кода вторую и третью строки:
call:# "adm" "info" "ivanov" "petrov" "sidorov"
exit /b.

[rosalin]

скрипт работает разобрался, спасибо!