[решено] переименование файлов

[Slava91]

Добрый день!!!
Необходимо реализовать переименование всех файлов с расширением jpg в файлы с расширением jpeg, находящихся в папке, указанной пользователем. Вывести на экран список переименованных файлов и их общее количество.

[Foreigner]

@echo off
setlocal

pushd %1 || goto:eof

for /f "tokens=*" %%i in ('dir /b *.jpg') do (

set /a n+=1
ren "%%i" "%%~ni.jpeg"
echo %%~ni

)

echo ---
echo %n%

popd

Путь к папке задается параметром к батнику.

[Slava91]

А где параметр указать?

[Foreigner]

А где параметр указать? »
O.o Ладно, укажи в самом батнике:

@echo off
setlocal

set "folder=D:\Pictures\The Last Friday"
pushd "%folder%" || goto:eof

....

[Slava91]

переименовывает и это хорошо. Но не выводит список и количество переименованных файлов. И как реализовать выбор папки через параметр если не сложно поясните для развития.

в смысле список то он выводит но закрывает сразу после выполнения нужно сделать так что бы он попросил действия пользователя перед закрытием

[Iska]

И как реализовать выбор папки через параметр если не сложно поясните для развития. »
Например, так: CMD/BAT: использование стандартных GUI-диалогов выбора папки и файла (http://forum.script-coding.com/viewtopic.php?id=4514).

в смысле список то он выводит но закрывает сразу после выполнения нужно сделать так что бы он попросил действия пользователя перед закрытием »
Добавьте «pause» в пакетный файл, если Вы вызываете его непосредственно из-под Проводника.

[Slava91]

добавил pause алгоритм работает единственное никак не пойму как мне добавить данный код в батник чтобы все заработало?
@echo off
setlocal

for /f "tokens=2 delims=:" %%i in ('chcp') do (
set sPrevCP=%%i
chcp 1251 >nul
)

for /f "usebackq delims=" %%i in (
`@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
1^|more`
) do set sFolderName=%%i

chcp %sPrevCP% >nul

if defined sFolderName (
echo Выбрана папка: [%sFolderName%].
) else (
echo Папка не была выбрана.
)

endlocal
exit /b 0

[Iska]

Не проверялось:
@echo off
setlocal enableextensions enabledelayedexpansion

for /f "tokens=2 delims=:" %%i in ('chcp') do (
set sPrevCP=%%i
chcp 1251 >nul
)

for /f "usebackq delims=" %%i in (
`@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
1^|more`
) do set sFolderName=%%i

chcp %sPrevCP% >nul

if defined sFolderName (
pushd "%sFolderName%" || goto:eof

for /f "tokens=*" %%i in ('dir /b *.jpg') do (

set /a n+=1
ren "%%i" "%%~ni.jpeg"
echo %%~ni
)

echo ---
echo %n%

popd
) else (
echo Папка не была выбрана.
)

endlocal
exit /b 0

[Slava91]

где указывается параметр?
куда необходимо мне вставить этот код?

скажем так этим я никогда не занимался, но тут встала задача. Поэтому понимание у меня начальный уровень.

[Iska]

где указывается параметр? »
Там нет никакого параметра, поскольку:
как реализовать выбор папки »
Например, так: CMD/BAT: использование стандартных GUI-диалогов выбора папки и файла. »
как мне добавить данный код в батник чтобы все заработало? »
Не проверялось: »

куда необходимо мне вставить этот код? »
Скопировать приведённый код. Создать файл с расширением «.cmd». Вставить скопированное в этот файл. Сохранить файл в кодировке OEM/866. Пользоваться.

[Slava91]

Пишет что режим вывода команд echo отключен и не выводит количество переименованных файлов

[Iska]

Замените «echo %n%» на «echo !n!».

[Slava91]

Проблема решена всем огромное спасибо!!!
Замечательный bat'ник вышел