[решено] Скрипт vbs для создания ярлыка на рабочем столе

[angel_lyucifer]

Всем привет!
Я нашёл у вас на форуме нужный мне скрипт для создания ярлыков.
Но он у меня не работает и выдаёт ошибку, я не просто не понимаю что тут не так? Уважаемые знатоки, посмотрите его и если можете исправте пожалуйста?

@set @x=0 /*
@cscript/nologo /e:jscript "%~f0" "%~dp0file.exe" "%~dp0"
@exit */
sh=WScript.CreateObject("WScript.Shell")
lk=sh.CreateShortcut(sh.SpecialFolders("Desktop")+"\\file.lnk")
lk.TargetPath=WScript.Arguments(0)
lk.WorkingDirectory = WScript.Arguments(1)
lk.Save()

[Iska]

angel_lyucifer, потому что это пакетный файл — гибрид из пакетного файла, вызова JScript-интерпретатора и VBScript-кода.

Сохраняете его как «Name.cmd» и вызываете, например:
E:\Песочница\0336\0005.cmd
В результате получаете на Рабочем столе ярлык «file.lnk», указывающий на «file.exe», находящийся рядом с пакетным файлом — т.е.: «E:\Песочница\0336\file.exe».

Одним словом, крайне неудачный выбор.

[angel_lyucifer]

Одним словом, крайне неудачный выбор. »
Проблема такая, у меня есть файл Vlp.exe у него может быть любая директория, но мне нужно создать ярлык скриптом, этот скрипт будет лежать рядом с файлом...

[angel_lyucifer]

Iska »
Всё понял, спасибо...

[Iska]

у меня есть файл Vlp.exe у него может быть любая директория, но мне нужно создать ярлык скриптом, этот скрипт будет лежать рядом с файлом... »
Так:
Option Explicit

Dim strFileName

Dim objFSO
Dim strPath2File
Dim objFile


strFileName = "Vlp.exe"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

strPath2File = objFSO.BuildPath(objFSO.GetParentFolderName(WScript.ScriptFullName), strFileName)

If objFSO.FileExists(strPath2File) Then
Set objFile = objFSO.GetFile(strPath2File)

With WScript.CreateObject("WScript.Shell")
With .CreateShortcut(objFSO.BuildPath(.SpecialFolders.Item("Desktop"), objFSO.GetBaseName(strFileName) & ".lnk"))
.TargetPath = objFile.Path
.WorkingDirectory = objFile.ParentFolder.Path

.Save
End With
End With

Set objFile = Nothing
Else
WScript.Echo "File [" & strPath2File & "] not found near this script."
WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0

[angel_lyucifer]

Iska »
Скрипт, очень хорошей!
А как добавить описание для этого ярлыка?

[Iska]

With WScript.CreateObject("WScript.Shell")
With .CreateShortcut(objFSO.BuildPath(.SpecialFolders.Item("Desktop"), objFSO.GetBaseName(strFileName) & ".lnk"))
.TargetPath = objFile.Path
.WorkingDirectory = objFile.ParentFolder.Path
.Description = "Это мой ярлык"

.Save
End With
End With

[angel_lyucifer]

Большое спасибо, Iska! =)

[deminand]

а как выполнить его на удаленном компьютере для определенного пользователя. ПК в домене.

[Iska]

а как выполнить его на удаленном компьютере для определенного пользователя. ПК в домене. »
В составе LOGON-скрипта, например.

[deminand]

а без участия политик ?.

[Iska]

«Для определённого пользователя» — никак. Можно только «от имени указанного пользователя». То есть, нужно знать его пароль. Чего в нормальном окружении быть не должно.

P.S. Вы уверены, что ярлык нужен отдельным указанным пользователям, а не всем?

[deminand]

опреденно вы правы, процесс чтоб попасть в свой профиль должен быть от имени пользователя, однако:
1) скрипт нашел нужный ПЭВМ
2) скрипт помнит нужного пользователя пользователя
3) скрипт создает нужный ярлык - путь на запуск того что надо.
4) скрипт создает права - безопасность на выполнение файла, добавив что вася пупкин может запускать этот файл
3) скрипт засовывает на нужном компе в профиль пользователю нужный файл.

пункт 1 и 3 можно поменять местами.

при этом алгоритме "запуск от имени" для создания ярлыка непотребуется, достаточно пермишны установить мог админ через скрипт.

упрощено:
создал сам себе ярлык
запихнул в профиль пользователя на нужном компе
там выставил на файл .lnk пермишионалы

[Iska]

создал сам себе ярлык
запихнул в профиль пользователя на нужном компе »
Не делайте так.

скрипт засовывает на нужном компе в профиль пользователю нужный файл. »
И как именно Вы определите, где именно у конкретно взятого пользователя на конкретной машине расположен Рабочий стол? Впрочем, достаточно первого.

[BOBAT]

Цитата Iska:
И как именно Вы определите, где именно у конкретно взятого пользователя на конкретной машине расположен Рабочий стол? »
%USERPROFILE%\Desktop\

[Iska]

BOBAT, откуда Вы возьмёте «%USERPROFILE%» пользователя «X» для машины «Y» при исполнении скрипта под пользователем, отличным от «X», на машине «Z»? Далее, откуда такая уверенность, что папка Рабочего стола именуется исключительно «Desktop»? «Это не есть факт, месье Дюк» (с).

[venom05]

Есть вопрос по созданию ярлыка запуская скрипт из гиены,кто подскажет?

[Iska]

Есть вопрос по созданию ярлыка запуская скрипт из гиены,кто подскажет? »
Есть вопрос по толкованию понятия «гиена», кто подскажет?

[venom05]

Гиена утилита с помощью которой я админю компы в домене,типа DameWare NT Utilities

с помощью гиены я запускаю скрипт на определенном компьютере,проблема заключается в том-не могу никак додумать создание ярлыка на компе где запустил скрипт,вот пример
Set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")

Set Argum = WScript.Arguments
strComputer = Argum(0)

Dim oShell
Dim oShortCut

set oShell = WScript.CreateObject ("WScript.Shell")
DesktopPath = oShell.SpecialFolders("AllUsersDesktop")

Set oShortCut = oShell.CreateShortcut(DeskTopPath & "\\" & strComputer & "\Proga.lnk")
oShortCut.TargetPath = "\\" & strComputer & "C:\Proga\Proga.exe"
oShortCut.Save

в конце выдает ошибку: "C:\Users\Public\Desktop\имя компа\Ярлык.lnk"

[Iska]

в конце выдает ошибку: "C:\Users\Public\Desktop\имя компа\Ярлык.lnk" »
Точное сообщение об ошибке покажите (используйте «Ctrl-C» или «Alt-PrintScreen»).