PDA

Показать полную графическую версию : [решено] Получить имя самого нового файла


alexbunt
21-11-2013, 11:56
Здравствуйте. Помогите написать скрипт vbs
Есть папка "D:\test" в ней > 2 файлов. Названия неизвестны, расширения тоже.
Задача получить имя самого нового (по дате создания) файла среди всех. Имя в переменную, все остальные файлы удалить.

Iska
21-11-2013, 15:36
Option Explicit

Dim strFolder

Dim objFile
Dim strFile
Dim dtDateCreatedNewest


strFolder = "D:\test"

With WScript.CreateObject("Scripting.FileSystemObject")
If .FolderExists(strFolder) Then
strFile = ""
dtDateCreatedNewest = #01/01/1970#

For Each objFile In .GetFolder(strFolder).Files
If objFile.DateCreated > dtDateCreatedNewest Then
If .FileExists(strFile) Then
.GetFile(strFile).Delete True
End If

strFile = objFile.Path
dtDateCreatedNewest = objFile.DateCreated
Else
objFile.Delete True
End If
Next

WScript.Echo strFile, dtDateCreatedNewest
Else
WScript.Echo "Folder [" & strFolder & "] not found."
End If
End With

WScript.Quit 0

alexbunt
21-11-2013, 15:54
Iska, гигантская благодарность вам!




© OSzone.net 2001-2012