команда if

[e9990638]

Привет всем.
Помогите правильно написать команду для cmd-файла. В данном случае с IF.
Моя команда (установить обновления в текущем каталоге с подпапками, вывести текущую информацию, и пропустить файл (не делать с ним ничего) e999-64.MSP

for /R . %%f in (*.msp) do (
if %%f NEQ e999-64.MSP (
echo Processing "%%f" Update...
msiexec /p %%f /qn /norestart
)
)

Выполняется вроде бы все, кроме if.

[Petya V4sechkin]

e9990638, исправьте строку:
if /i %%~nxf NEQ e999-64.MSP (

[e9990638]

Petya V4sechkin, Спасибо.

P.S. А какой будет код, если файлов будет больше.
Например: e999-64.MSP; e999-32.MSP; e999-17.MSP.

Спасибо за ответ.

[Iska]

Например, так (не проверялось):
@echo off
setlocal enableextensions enabledelayedexpansion

for /r "." %%i in (*.msp) do (
set /a bFound = 0

for %%j in ("e999-64.MSP" "e999-32.MSP" "e999-17.MSP") do if /i "%%~j" equ "%%~i" set /a bFound = 1

if !bFound! neq 1 (
echo Processing "%%~i" Update...
msiexec.exe /p "%%~i" /qn /norestart
)
)

endlocal
exit /b 0

[e9990638]

Iska, не работает.

[Iska]

Например, так (не проверялось): »
Iska, не работает. »
Проверил. Исправьте одну строку так:
for %%j in ("e999-64.MSP" "e999-32.MSP" "e999-17.MSP") do if /i "%%~j" equ "%%~nxi" set /a bFound = 1

[e9990638]

Iska, Спасибо, все работает.