[решено] Как выделить каждую определенною строку в текстовом файле

[KooDI]

Доброго времени суток всем
Как можно сделать так, для примера, чтоб с каждой третей строки копировался весь текст и записывался в другой документ построчно

[Iska]

Например, так:
Option Explicit

Dim strSourceFile
Dim objFSO
Dim objTS

Dim lngCount

If WScript.Arguments.Count = 1 Then
strSourceFile = WScript.Arguments.Item(0)

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strSourceFile) Then
Set objTS = objFSO.CreateTextFile(strSourceFile & ".export.txt", True)

With objFSO.OpenTextFile(strSourceFile)
lngCount = 0

Do Until .AtEndOfStream
lngCount = lngCount + 1

If lngCount = 3 Then
objTS.WriteLine .ReadLine()

lngCount = 0
Else
.SkipLine
End If
Loop

.Close
End With

objTS.Close

Set objTS = Nothing
Else
WScript.Echo "Source file [" & strSourceFile & "] not found"
End If

Set objFSO = Nothing
Else
WScript.Echo "Usage: " & WScript.ScriptName & " <Source file>"
End If

WScript.Quit

[KooDI]

А где надо изменять значения, то которое определяет нужную мне строку, я изменял в этой строке If lngCount = 3 Then з 3 на 2 и при выполнение скрипта ничего не происходило

[Iska]

и при выполнение скрипта ничего не происходило »
KooDI, приведите Ваш код.

[KooDI]

Просто в вашем коде изменил 3 на 2

Option Explicit

Dim strSourceFile
Dim objFSO
Dim objTS

Dim lngCount

If WScript.Arguments.Count = 1 Then
strSourceFile = WScript.Arguments.Item(0)

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strSourceFile) Then
Set objTS = objFSO.CreateTextFile(strSourceFile & ".export.txt", True)

With objFSO.OpenTextFile(strSourceFile)
lngCount = 0

Do Until .AtEndOfStream
lngCount = lngCount + 1

If lngCount = 2 Then
objTS.WriteLine .ReadLine()

lngCount = 0
Else
.SkipLine
End If
Loop

.Close
End With

objTS.Close

Set objTS = Nothing
Else
WScript.Echo "Source file [" & strSourceFile & "] not found"
End If

Set objFSO = Nothing
Else
WScript.Echo "Usage: " & WScript.ScriptName & " <Source file>"
End If

WScript.Quit

[Iska]

KooDI, взял приведённый код. Создал текстовый файл:
1
2
3
4
5
6
7
8
9
10

Запустил скрипт, указав аргументом текстовый файл. Получил новый текстовый файл:
2
4
6
8
10


А у Вас? Если не так — упакуйте Ваш текстовый файл в архив и выложите сюда или на RGhost.ru.

[KooDI]

Не знаю почему но, сейчас все работает.
Спасибо огромное