[решено] Подключение к wi-fi с паролем

[Gen_prot]

Нужен батник для подключение к wifi сети test_wifi с паролем pass

Сколько искал - находил только такой вариант - что импортируются настройки из xml файла и потом можно подключиться.
netsh wlan add profile filename=file_nastrojki.xml i=*

а хочется найти что то вроде netsh wlan connect name="test_wifi" key="pass"

[Vadikan]

Gen_prot, а что-то мешает сначала из батника сформировать командой echo XML (http://msdn.microsoft.com/en-us/library/aa370029(v=VS.85).aspx) с ключом? :)

[Gen_prot]

Предполагал такой ответ, но мало ли есть иной вариант =)

[WoW]

Приветствую!
Подскажите, как можно подключиться к точке Wi-Fi с паролем?
Нашел только одну тему, но без решения,
http://forum.oszone.net/post-2096352.html

Если BAT файлом сложно это решить, то можно и на VBS. Спасибо!

[Iska]

но без решения, »
Чем не устраивает решение, изложенное во втором сообщении:
а что-то мешает сначала из батника сформировать командой echo XML с ключом? »
?!

[WoW]

Iska,
я просто не понимаю, как сделать. Из меня тот еще писака скриптов.

[Vadikan]

WoW, а в текстовом редакторе вы можете создать XML на основе образца кода? Совет: используйте копирование и вставку.

[norem]

батник для настройки 3х вайфаев

@Echo OFF
Title WiFi Profile Manager
Color 0E
Mode 50,15

:Menu
Cls & Echo.
Echo ========================
Echo ^<^<^< Setup Menu ^>^>^>
Echo ========================
Echo.
Echo ^<1^> Option One
Echo ^<2^> Option Two
Echo ^<3^> Option Three
Echo ^<4^> Option ALL
Echo ^<5^> Exit

Echo.

Set "choice="
Set /p "choice= Option: "
IF NOT DEFINED choice GOTO :Menu

IF "%choice%" == "1" Call :Option1
IF "%choice%" == "2" Call :Option2
IF "%choice%" == "3" Call :Option3
IF "%choice%" == "4" Call :All
IF "%choice%" == "5" Goto :EOF

Exit /B

:Option1
set "SSID=SSID_1"
set "SharedKey=Password_1"
set "xml_name=option1.xml"
Call :XML "%SSID%" "%SharedKey%" "%xml_name%"
netsh wlan add profile filename=%xml_name%
Del /F /Q "%xml_name%" >nul
Goto :eof

:Option2
set "SSID=SSID_2"
set "SharedKey=Password_2"
set "xml_name=option2.xml"
Call :XML "%SSID%" "%SharedKey%" "%xml_name%"
netsh wlan add profile filename=%xml_name%
Del /F /Q "%xml_name%" >nul
Goto :eof

:Option3
set "SSID=SSID_3"
set "SharedKey=Password_3"
set "xml_name=option3.xml"
Call :XML "%SSID%" "%SharedKey%" "%xml_name%"
netsh wlan add profile filename=%xml_name%
Del /F /Q "%xml_name%" >nul
Goto :eof

:All
Call :Option1
Call :Option2
Call :Option3
Goto :EOF

:XML [XML setting File form]
:: Take 4 inputs: Name, SSID, SharedKey & output xml file name.

set "SSID=%~1"
set "SharedKey=%~2"
set "output=%~3"
(
echo ^<?xml version="1.0"?^>
echo ^<WLANProfile xmlns="http://www.microsoft.com/networking/WLAN/profile/v1"^>
echo ^<name^>%SSID%^</name^>
echo ^<SSIDConfig^>
echo ^<SSID^>
echo ^<name^>%SSID%^</name^>
echo ^</SSID^>
echo ^<nonBroadcast^>true^</nonBroadcast^>
echo ^</SSIDConfig^>
echo ^<connectionType^>ESS^</connectionType^>
echo ^<connectionMode^>auto^</connectionMode^>
echo ^<MSM^>
echo ^<security^>
echo ^<authEncryption^>
echo ^<authentication^>WPA2PSK^</authentication^>
echo ^<encryption^>AES^</encryption^>
echo ^<useOneX^>false^</useOneX^>
echo ^</authEncryption^>
echo ^<sharedKey^>
echo ^<keyType^>passPhrase^</keyType^>
echo ^<protected^>false^</protected^>
echo ^<keyMaterial^>%SharedKey%^</keyMaterial^>
echo ^</sharedKey^>
echo ^</security^>
echo ^</MSM^>
echo ^</WLANProfile^>
)>"%output%"
Goto :EOF

[yel]

Полезный батник, спасибо