Автоматическая распечатка отчета

[Bigsom85]

Нужно написать бат для автоматической распечатки отчета о принтере. У нас в офисе имеется 6 пользователей, 5 принтеров. Принтер Xerox 3600 сетевой. Задача:
1) Открыть Эксплорер
2) перейти по адресу принтера
3) открыть просмотр
4) отправить на печать
5) перейти по следующему адресу
6) открыть просмотр
7) отправить на печать
8) ........ а так далее.

[Iska]

Bigsom85, смотрите пример кода здесь (http://forum.oszone.net/post-1236507.html#post1236507).

[Bigsom85]

:o не понял?

что означает On Error Resume Next так начинается составление кода?

[Iska]

Bigsom85, расставьте, пожалуйста, заглавные буквы и знаки препинания в Ваших предложениях, дабы в них появился смысл.

[Bigsom85]

On Error Resume Next
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objIE = CreateObject("InternetExplorer.Application")
strFile = Wscript.arguments.Item(0)
strFile = objFSO.GetAbsolutePathName(strFile)
If Not(objFSO.FileExists(strFile)) Then
WScript.Echo "Файл не найден"
WScript.Quit End If objIE.Visible = True objIE.Navigate strFile
While objIE.Busy
WScript.Sleep 100 Wend
objIE.ExecWB 6, 2 WScript.Sleep 1000
objIE.Quit

Как его можно разобрать? Вы мне этот код дали для примера, не так ли?!

[Iska]

Bigsom85, попробуйте так (по этому (http://forum.script-coding.com/viewtopic.php?pid=29234#p29234) коду):
Option Explicit

Const READYSTATE_COMPLETE = 4

Const OLECMDID_PRINT = 6
Const OLECMDEXECOPT_DONTPROMPTUSER = 2

Dim strAddress
Dim boolDone


With WScript.CreateObject("InternetExplorer.Application", "IE_")
.Visible = True

For Each strAddress In Array("http://www.script-coding.com", "http://pda.mail.ru", "http://www.google.com")
.Navigate strAddress

Do
WScript.Sleep 100
Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE

boolDone = False

.ExecWB OLECMDID_PRINT, OLECMDEXECOPT_DONTPROMPTUSER

Do
WScript.Sleep 100
Loop Until boolDone
Next

.Quit
End With

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub IE_PrintTemplateTeardown(ByVal pDisp)
boolDone = True
End Sub
'=============================================================================
«"http://www.script-coding.com", "http://pda.mail.ru", "http://www.google.com"» — меняете на адреса/Url страниц Ваших принтеров. После того, как убедитесь, что всё работает как надо — строку «.Visible = True» можно будет закомментировать.

[Bigsom85]

Все отлично распечатывает!!!! Большой спс