[решено] Скрипт по изменению реестра

[T3D]

Здравствуйте.
Может кто-нибудь подсказать реализацию такого а/р на любом языке:
1) Задаём "переменную для поиска" и переменную для замены (можно правкой вручную, можно с окном запроса);
2) Ищем переменную для поиска в реестре;
3) Заменяем найденную переменную на "переменную для замены";

Заранее благодарен за любую помощь.

[amel27]

- предположу, что под "переменной" понимается "параметр" реестра, так?
- и всё-таки: заменяем переменную (через удаление) или только её значение?
- кроме имени нужно обязательно знать тип параметра, например строка: REG_SZ

[Foreigner]

3) Заменяем найденную переменную на "переменную для замены" »
И благополучно убиваем 100500 похожих вхождений. Например находим все PATH в HKCU:

> reg query hkcu /v "PATH" /s

HKEY_CURRENT_USER\Environment
PATH REG_SZ C:\Users\Dmitry\BIN;C:\Users\Dmitry\BIN\POSH;C:\Users\Dmitry\BIN\GNU\bin

HKEY_CURRENT_USER\Software\7-Zip
Path REG_SZ C:\Program Files\7-Zip\

HKEY_CURRENT_USER\Software\Sysinternals\Process Explorer
Path REG_SZ c:\Users\Dmitry\BIN\SYSINTERNALS\procexp64.exe

Поиск завершен: найдено совпадений: 3.

[T3D]

- предположу, что под "переменной" понимается "параметр" реестра, так? »
Так.
- и всё-таки: заменяем переменную (через удаление) или только её значение? »
Только значениеИ благополучно убиваем 100500 похожих вхождений. Например находим все PATH в HKCU: »
Искаться будет уникальный IP-адрес, так что ничего лишнего не удалиться

[Foreigner]

Искаться будет уникальный IP-адрес, так что ничего лишнего не удалиться »
Ставь задачу конкретней. Подозреваю, что искать надо не по всему реестру, может даже искать не надо, а заранее известен раздел\ключ\параметр ( или сократить область поиска до раздел\ключ ) и надо только узнать/поменять его значение.

[SendMessage]

Для строковых значений. Как заготовка.
' Для совпадающих строке поиска значений (REG_SZ)

Option Explicit

Dim SectionName
Dim tmpRegFile
Dim FindValue
Dim AddValue
Dim objWSS
Dim objFSO
Dim RegFile
Dim CurrSection
Dim GetLine
Dim KeyName
Dim strPrompt
Dim ReturnValue

SectionName = "HKEY_CURRENT_USER\Software"
tmpRegFile = "z:\tmp.reg"
FindValue = "Строка поиска"
AddValue = "Строка замены"

Set objWSS = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")

objWSS.Run "regedit /e " & tmpRegFile & " """ & SectionName & """", 2, True

Set RegFile = objFSO.OpenTextFile(tmpRegFile, 1, True, -1)

Do While RegFile.AtEndOfStream <> True
GetLine = RegFile.ReadLine
If Left(GetLine, 6) = "[HKEY_" Then
CurrSection = Mid(GetLine, 2, Len(GetLine) - 2)
Else
If InStr(GetLine, FindValue) Then
strPrompt = "Вы желаете заменить значение ключа " & GetLine & vbNewLine & _
"в разделе " & CurrSection & vbNewLine & _
"на значение """ & AddValue & """?"
ReturnValue = MsgBox(strPrompt, 35, "Замена в реестре")
If ReturnValue = 6 Then
KeyName = Replace(Split(GetLine, "=")(0), """", "")
If KeyName = "@" Then KeyName = ""
objWSS.RegWrite CurrSection & "\" & KeyName, AddValue, "REG_SZ"
ElseIf ReturnValue = 2 Then
Exit Do
End If
End If
End If
Loop

RegFile.Close

'Следующая строка закомментирована для возможности отката изменений
'objFSO.DeleteFile tmpRegFile

Set objWSS = Nothing
Set objFSO = Nothing

MsgBox "Скрипт завершил работу"

WScript.Quit
Через промежуточный файл для убыстрения.