[решено] Взять значение из свойства файла

[sov44]

Подскажите, возможно ли посредством командного файла зайти в свойства файла и записать оттуда значение? В частности интересует, как в перечне файлов .msp войти в свойства, из вкладки "Общие" строки "Изменен:" взять только значение даты (например 24 января 2010г.), сравнить с датами в других .msp и вывести в echo самую позднюю дату в формате 24.01.2010

[amel27]

по всем msp-файлам текущего каталога:
@echo off
for /f "delims=" %%d in ('dir/b/od *.msp') do set "$d=%%~td"
echo %$d:~,10%

pause>nul

[gora]

@Echo Off
SetLocal EnableDelayedExpansion
:: Обрабатываемая папка
Set Folder=n:\_My_ADDONs\_DotNet11_40\DNet1140\DotNet40\NetMSP

Set lastDate=
For /F "Delims=" %%i In ('DIR /B/S/A-D "%Folder%\*.msp"') Do (
Set datchng=%%~ti
If "!datchng:~6,4!!datchng:~3,2!!datchng:~0,2!" GTR "!lastDate!" Set lastDate=!datchng:~6,4!!datchng:~3,2!!datchng:~0,2!
)
Echo !lastDate:~6,2!.!lastDate:~4,2!.!lastDate:~0,4!
Pause>Nul


Упс... Опоздал. :)

[ferget]

а часы и минуты как добавить?

все разобрался

[sov44]

Подскажите, почему не работает скрипт с указанием папки поиска?

@Echo Off
:: Обрабатываемая папка
Set Folder=h:\XPSP3\FINISH\I386\SVCPACK

for /f "delims=" %%d in ('dir/b/od "%Folder%\*.CA_"') do set "$d=%%~td"
echo %$d:~,10%

pause>nul

[ferget]

вот так работает

@Echo Off
:: Обрабатываемая папка
Set Folder=h:\XPSP3\FINISH\I386\SVCPACK

for /f "delims=" %%d in ('dir /b/s/a-d "%Folder%\*.CA_"') do set "$d=%%~td"
echo %$d:~,10%

pause>nul

[sov44]

ferget, скрипт заработал, но как ни странно, показывает не самую позднюю дату, по сравнению со скриптом gora

[ferget]

попробуйте /od добавить

[sov44]

Не могу понять, почему не работает отображение максимальной даты. Подскажите, что не так?

@echo off
SetLocal enabledelayedexpansion

set tt2=%~dp0Msp
for /f "delims=" %%d in ('dir /b /od "%tt2%\*.msp"') do set "$d=%%~td"
Echo %$d:~,10%
pause

[sov44]

Никто не хочет объяснить, почему не работает скрипт постом выше?

[gora]

sov44, добавьте ключ /s в строку после dir.

[sov44]

gora, огромное спасибо, всё сработало!