[решено] Обработать все файлы в папке с помощью скрипта

[dark-------13]

Здравствуйте,

Есть скрипт который ищет файл с текущей датой на диске Y:\ копирует его в папку V и шифрует его там, а как сделать тоже самое - если файлов несколько за текущую дату на диске Y:\ (или в указанной папке) - хотелось бы их найти и зашифровать по отдельности
Заранее спасибо.

@echo off
setlocal
rem где pushd папка с исходными файлами
pushd "Y:\"

for /f "tokens=*" %%i in (' dir /b *.txt ') do (

for /f "tokens=1" %%j in ( "%%~ti" ) do if "%%j"=="%date%" set "file=%%i"

)
rem файл из папки с исходными файлами копируется в папку назначения и только после шифруется
copy "%file%" "D:\V"
popd
cry "D:\V\%file%"

[amel27]

@echo off
pushd "Y:\"

for /f "tokens=*" %%i in ('dir /b *.txt') do (
for /f "tokens=1" %%j in ("%%~ti") do if "%%j"=="%date%" (
copy "%%i" "D:\V\"
cry "D:\V\%%i"
))
popd

[dark-------13]

Батник отрабатывает но файлы не копирует указываю вместо Y:\ D:\vgo файлы имеют русские имена

[amel27]

указываю вместо Y:\ D:\vgo »
@echo off
set $SRC=D:\vgo
set $DST=D:\V

pushd "%$SRC%"
for /f "tokens=*" %%i in ('dir /b *.txt') do (
for /f "tokens=1" %%j in ("%%~ti") do if "%%j"=="%date%" (
copy "%%i" "%$DST%\"
cry "%$DST%\%%i"
))
popd