[решено] Авто запуск

[Miko]

Здравствуйте. Возможно не очень корректно указал тему но все же..

Не так давно я просил с помощью bat файл скопировать текст и сохранить его в текстовый файл. Получилось :

@(for /f "tokens=1* delims=: " %%a in ('findstr /birc:" *MPP-Width:" "C:\Program Files\File.txt"') do @echo %%b ) >MPP-Width.txt @(for /f "tokens=1* delims=: " %%a in ('findstr /birc:" *MPP-Height:" "C:\Program Files\File.txt"') do @echo %%b ) >MPP-Height.txt

Возможно ли сделать проверку в этом файле. Что бы было примерно так:

Есть программа "Test.exe" нужно что бы bat файл смотрел,если запустили test.exe - Он выполняет то что написано выше.

И еще,не могли бы вы написать обратный вариант bat файла который указан выше:

Bat файл должен найти строку "MPP-Height:" и "MPP-Width:" и дописать к этим строкам число которое я укажу. К примеру в File.txt указано :

"MPP-Height: 200" и "MPP-Width: 300" нужно что бы bat заменил на "MPP-Height: 300" и "MPP-Width: 400"

За ранее спасибо.

[amel27]

что бы bat файл смотрел,если запустили test.exe - Он выполняет то что написано выше »
@echo off

tasklist|findstr /bic:"test.exe"&&(
for /f "tokens=1* delims=: " %%a in ('findstr /birc:" *MPP-Width:" "C:\Program Files\File.txt"') do >MPP-Width.txt echo %%b
for /f "tokens=1* delims=: " %%a in ('findstr /birc:" *MPP-Height:" "C:\Program Files\File.txt"') do >MPP-Height.txt echo %%b
)
К примеру в File.txt указано :
"MPP-Height: 200" и "MPP-Width: 300" нужно что бы bat заменил на "MPP-Height: 300" и "MPP-Width: 400" »конкретная реализация зависит от структуры и назначения файла,
@echo off

set L1=MPP-Height:200
set L2=MPP-Height:300
call :REPLN "c:\Program Files\File.txt" L1 L2

set L1=MPP-Width:300
set L2=MPP-Width:400
call :REPLN "c:\Program Files\File.txt" L1 L2

EXIT/B

:REPLN %file% ByRef %LineFrom% ByRef %LineTo%
::-------------------------------------------
SETLOCAL DisableDelayedExpansion
(for /f "usebackq tokens=*" %%a in ("%~1") do (set "$a=%%a"
SETLOCAL EnableDelayedExpansion
if /i "!$a!"=="!%~2!" set "$a=!%~3!"
echo !$a!
ENDLOCAL ))>"%~dpn0.tmp"
copy /y "%~dpn0.tmp" "%~1">nul&& del "%~dpn0.tmp"
ENDLOCAL& GoTo :EOF

P.S. касаемо названия темы:

1 - выполнение батником команды при наличии в системе процесса;
2 - замена строки в текстовом файле

[Miko]

Спасибо. Это то что нужно.

Возник еще один вопрос.. А можно заменить :
"MPP-Height: 200" и "MPP-Width: 300" нужно что бы bat заменил на "MPP-Height: 300" и "MPP-Width: 400"

На это:
"MPP-Height: 200" и "MPP-Width: 300" нужно что бы bat заменил на "MPP-Height: Файл который лежит в папке с bat" и "MPP-Width: Файл который лежит в папке с bat" - В принципе я могу это все оформить на Delphi но мне нужно на bat.

Если можно то хотелось бы готовый код.. Или "Очки" вручить.