[решено] Выполнение команды запуск sfx архива

[timon45]

Имеется образ WinPE нужно выполнить команду по запуску sfx архива PePrograms.exe с диска в этой же папке присутствует CopyRam.bat содержащий строки:
@echo off
Color 1e
Cls
Echo Copying files ...
md "b:\Programs\$Wim$"
copy /y "%~dp0*.wim" "b:\Programs\$Wim$"
if not %ErrorLevel%==0 Goto _Err
Cls
Echo UnMount wim files ...
Call "%Temp%\UnMount.cmd"|find "["
Del "%Temp%\UnMount.cmd"
Echo. 2>"%Temp%\UnMountB.cmd"
cd /d "b:\Programs\$Wim$"
Cls
Echo Mounting wim files ...
For %%i in (*.wim) Do call :_Mount "%%~dpnxi"
Echo rd /s /q "b:\Programs\$Wim$">>"%Temp%\UnMountB.cmd"
GoTo :Eof

:_Mount
md "b:\Programs\%~n1"
imagex.exe /mountrw "%~1" 1 "b:\Programs\%~n1"|find /i "b:\Programs\"
Echo imagex /unmount "b:\Programs\%~n1">>"%Temp%\UnMountB.cmd"
Echo rd /s /q "b:\Programs\%~n1">>"%Temp%\UnMountB.cmd"
GoTo :Eof

:_Err
rd /s /q "b:\Programs\$Wim$"
Color 4f
Echo Copying error !
pause>nul

какие строки нужно добавить чтобы это реализовать.

[Vadikan]

timon45, определите букву диска, запустите файл.
FOR %%d IN (c d e f g h i j k l m n o p q r s t u v w x y z) DO IF EXIST %%d:\<путь от корня>\PePrograms.exe SET CDROM=%%d:
start /wait %cdrom%\<путь от корня>\PePrograms.exe

[timon45]

не прокатило. попробую пояснить по подробнее.
Команда должна запустить PePrograms.exe который находится %cdrom%\PePrograms\PePrograms.exe, bat находится в этой же папке %cdrom%\PePrograms\CopyRam.bat, буква диска может меняться.

всё спасибо!, разобрался надо было просто написать.
start PePrograms.exe

[deepred]

timon45,

Если *.bat находится на диске в той же директори, что и Ваш архив, то:

start /wait "%~dp0\PePrograms.exe"

[gora]

start /wait "%~dp0\PePrograms.exe" »
Если команда в кавычках, то правильнее так:start /wait "" "%~dp0\PePrograms.exe" Первый параметр в кавычках в команде Start рассматривается как "заголовок"