Поиск и удаление значения в реестре

[vdereberya]

Здравствуйте!
Помогите в решении проблемы.
Задача такова: требуется сценарий (или пакетный файл), который бы искал, и удалял параметр из реестра. Заранее неизвестно где будет прописан нужный параметр, и как он будет назван. Известно его значение (например Totalcmd.exe). Помогите плиз, очень нужно!

[amel27]

неизвестно где будет прописан нужный параметр, и как он будет назван »какого типа параметр и в каком разделе (HKLM/HKCU/...) тоже неизвестно?.. можно просто выгрузить весь реестр в текстовый файл и выполнить построчный поиск, либо использовать сторонние утилиты типа RegFind из ресурскита Windows 2000, пример:


@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion

Call :RegValFind HKEY_USERS "%COMPUTERNAME%"
If Defined $KEY Echo REG DELETE "%$KEY%" /v "%$VAL%" /f

Exit /B

:RegValFind
For /F "Tokens=1* Delims==" %%i In ('2^>Nul regfind -y -i 0 -p %~1 %~2') Do (
If "%%j"=="" (If %%i==%~1 (Set $KEY=%~1) Else Set $KEY=!$KEY!\%%i) Else (
Set $VAL=%%i& Set $VAL=!$VAL:~0,-1!& Exit /B ))

[sov44]

Необходимо в реестре проверить содержимое разделов startupreg, startupfolder на наличие в них параметров и подразделов, в случае наличия параметров и подразделов, их удалить.

HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg
HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder

[amel27]

sov44, а не проще вместо проверки тупо удалить/создать всю ветку?

[sov44]

amel27, конечно проще, сделано так

@echo off
Reg delete "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg" /f
Reg delete "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder" /f
Reg add "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg" /f
Reg add "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder" /f

и так

@echo off
reg delete "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg" /va /f
for /f "skip=4 delims=" %%i in ('reg query "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg"') do reg delete "%%i" /f

reg delete "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder" /va /f
for /f "skip=4 delims=" %%i in ('reg query "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder"') do reg delete "%%i" /f

однако планирую добавить этот кусок в скрипт удаления временных файлов, который запускаю в день иногда по несколько раз. Хорошо ли будет по несколько раз в день сносить разделы startupreg, startupfolder ?

[sov44]

решение подсказали

@echo off
goto :start
:fn1
set n=--
for /f "skip=4 delims=" %%i in ('reg query %1') do (set n="%%i" & goto :next)
:next
if "%n:~1,1%"==" " reg delete %1 /va /f
for /f "skip=4 delims=" %%i in ('reg query %1') do reg delete "%%i" /f
exit /b
:start
call :fn1 "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg"
call :fn1 "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder"

[yurfed]

ребуется сценарий (или пакетный файл), который бы искал, и удалял параметр из реестра. Заранее неизвестно где будет прописан нужный параметр, и как он будет назван. »
Хоть тема и была создана ещё в 2010, но отзывы ещё не потеряли актуальность, попробую ответить.
Вы понимаете в какую байду ещё ввязались? Всё, что было озвучено в просьбе - полный бред
Заранее неизвестно где будет прописан нужный параметр, и как он будет назван. Известно его значение (например Totalcmd.exe) »Типа - иди туда, не знаю куда. Принеси то, не знаю что.
По сути это целый проэкт, довольно ответственный, лезть в реестр и что-то там исправлять и искать.
Такие вещи делаются не с кандачка и не с коленки.
и то, что вам подсказали - решение подсказали » - полная ерунда
Я не умоляю знаний подсказавших хелперов, но ребята, будьте более в реальности, чем в своих кодах.

[sov44]

будьте более в реальности, чем в своих кодах »
А теперь по-русски.

[yurfed]

А теперь по-русски. »Вы полагаете что скрипты, которые предлагаются, во всём хороши?
А теперь по-русски. »
Хотите на албанском, если ещё не поняли?

[sov44]

Вы полагаете что скрипты, которые предлагаются, во всём хороши? »
предложте свой
Хотите на албанском, если ещё не поняли? »
откуда такая спесь? пофлудим?

[yurfed]

sov44, вы побазарить или мимо проходили?
Завязываем флуд, не относящийся к теме. Ок?
Отвечать не обязательно.

[amel27]

Хорошо ли будет по несколько раз в день сносить разделы startupreg, startupfolder ? »Если работает - не вижу препятствий... Единственный случай, когда этот способ может не подойти - наличие специальных прав на ветку, которые нужно сохранить (при удалении ветки права удаляются).
решение подсказали »
- удаляет все ключи и лишь один параметр (тот что "по умолчанию"), это и нужно?
- может не работать на других версиях Windows (значение в "skip=4")

[sov44]

- может не работать на других версиях Windows (значение в "skip=4") »
а как надо? Подскажите.
ещё вопрос, есть код ( вроде работает :) )

rem Удаление не запускаемых приложений в окне msconfig с проверкой их наличия
rem блок скрипта настроен на работу до 10 числа каждого месяца

set "tmr=%date:~0,2%"
If %tmr% LEQ 10 (

call :fn1 "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupreg"
call :fn1 "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\startupfolder"

:fn1
set n=--
for /f "skip=4 delims=" %%i in ("'reg query %1'2>Nul" ) do (set n="%%i" & goto :next)

:next
if "%n:~1,1%"=="H" (
reg delete %1 /va /f 1>Nul 2>&1
for /f "skip=4 delims=" %%i in ('reg query %1') do reg delete "%%i" /f 1>Nul 2>&1
)
)

как правильно записать отправку в nul
"'reg query %1'2>Nul" или "'reg query %1'2^>Nul" ???

[El Sanchez]

а как надо? Подскажите. »
Перенаправить вывод команды на вход Find/Findstr, например, reg query параметры|find /i "REG_SZ"
как правильно записать отправку в nul »

...('reg query %1 2^>nul')...

[sov44]

Перенаправить вывод команды на вход Find/Findstr »
покажите на примере, я пока не силён в cmd.

[El Sanchez]

покажите на примере »
sov44, прочитать, запомнить, воспроизвести. Буду спрашивать :)

По сути подавляющее большинство батников представляет собой циклическую обработку результатов вывода команды, содержащего нам нужную информацию. К сожалению вывод команды редко дает сразу нужный результат в нужном виде, поэтому фильтровать вывод необходимо. В качестве примера будем определять букву системного диска из реестра Windows 7/Windows XP.

Буква системного диска находится в реестре в кусте HKEY_CURRENT_USER\Volatile Environment, строковый (REG_SZ) параметр HOMEDRIVE. Определим значение этого параметра при помощи утилиты командной строки reg.exe, синтаксис которой можно посмотреть в справке reg.exe /?.


c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE

! REG.EXE VERSION 3.0

HKEY_CURRENT_USER\Volatile Environment
HOMEDRIVE REG_SZ C:


c:\temp>




c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE

HKEY_CURRENT_USER\Volatile Environment
HOMEDRIVE REG_SZ C:


c:\temp>


Видите разницу в выводах одной и той же команды? Количество строк неодинаково и строка с версией reg.exe в выводе для WinXP. Дело в разных версиях reg.exe в Win7 и WinXP, формирующих свой вывод по-разному, поэтому дальнейший разбор вывода командой for с указанием пропуска первых 4 строк вывода skip=4 на Win7 закончится ничем - for пропустит нужную нам строку. Вывод: результат нужно фильтровать, выделив нужную строку. Сделать это можно, используя команды find или findstr, перенаправив результат reg на вход команды find или findstr при помощи оператора piping (|). Используем find:


c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE|find "REG_SZ"
HOMEDRIVE REG_SZ C:

c:\temp>


"REG_SZ" - ищем строку с буквой по чему-нибудь, что отличает искомую строку от всех остальных. Все, строка найдена, причем независимо от ОС результат будет одинаковым.

Кстати, заменим Find "REG_SZ" на команду Findstr /N $ и посмотрим, на результат в WinXP и Win7. Параметр /N пронумерует обрабатываемые строки, а $ - шаблон для поиска, означающий, что будет произведен поиск строк, заканчивающихся на символ конца строки, а это все строки, включая пустые, т.е. просто посмотрим сколько строк вернет reg.exe в разных версиях Windows.


c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE|findstr /n $
1:
2:! REG.EXE VERSION 3.0
3:
4:HKEY_CURRENT_USER\Volatile Environment
5: HOMEDRIVE REG_SZ C:
6:

c:\temp>




c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE|findstr /n $
1:
2:HKEY_CURRENT_USER\Volatile Environment
3: HOMEDRIVE REG_SZ C:
4:

c:\temp>


Теперь видите, почему for с "skip=4" для WinXP получит искомую строку, а Win7 нет? Поэтому мы и пропустили результат reg через find. Но это не все. Что будет, если запрашиваемого параметра нет или куст указан несуществующий? Внесем изменения, добавив к HOMEDRIVE любой символ, например 1.


c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE1|find "REG_SZ"

Ошибка: Системе не удалось найти указанный раздел или параметр реестра

c:\temp>




c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE1|find "REG_SZ"
Ошибка: Не удается найти указанный раздел или параметр в реестре.

c:\temp>


В for это сообщение для обработки даже не попадет, т.к. принадлежит потоку StdErr команды reg, for же работает с StdOut, потоком, выводящим результат на экран в случае успешной отработки команды. Выход - перенаправить StdErr не на экран (значение по умолчанию), а в устройство nul, т.е. в никуда:
:

c:\temp>reg query "HKCU\Volatile Environment" /v HOMEDRIVE1 2>nul|find "REG_SZ"

c:\temp>


, где 2>nul и есть перенаправление StdErr (дескриптор потока StdErr равен 2, StdOut равен 1) в никуда. На экране ничего, хотя параметра HOMEDRIVE1 не существует.

Итак, строка найдена, теперь остается отделить букву диска от ненужных HOMEDRIVE, REG_SZ и пробелов. Для этого и нужна команда for, которая с параметром /f позволяет работать с результатом вывода других команд. Взглянем на нашу строку: " HOMEDRIVE REG_SZ C:" (привел в кавычках). Ее можно представить как строку с 3 подстроками (словами), разделенных пробелами. Осталось только указать for-у ключ разбора строки tokens=3 - делить строку на 3 части, 3-я подстрока в переменную (ключ delims (символ разделителя подстрок) не нужен, т.к. символы пробела и табуляции используется по умолчанию в качестве разделителей, а подстроки в нашей строке отделены пробелами) и вывести результат на экран или присвоить какой-либо переменной.


c:\temp>for /f "tokens=3" %a in ('reg query "HKCU\Volatile Environment" /v HOMEDRIVE 2>nul|find "REG_SZ"') do set drive=%a
Непредвиденное появление: 2>.

c:\temp>


Вот так облом, совсем не то, что ожидали увидеть, ведь интерпретатор решил, что была предпринята попытка перенаправления StdErr, а синтаксис for-а не закончился и нарушился. Чтобы указать интерпретатору, что символ > (как и |) являются частью синтаксиса for, а не попыткой перенаправления (>) или piping-а (|), нужно экранировать эти спецсимволы символом ^:


c:\temp>for /f "tokens=3" %a in ('reg query "HKCU\Volatile Environment" /v HOMEDRIVE 2^>nul^|find "REG_SZ"') do set drive=%a

c:\temp>set drive=C:

c:\temp>


Все, переменная drive теперь содержит букву диска.

[sov44]

El Sanchez, благодарю за полезный мануал, некоторое время был в отпуске, поэтому не сразу ответил в теме :)

С толкнулся с проблемой найти подраздел реестра в startupreg, startupfolder.

call :fn1 startupreg
call :fn1 startupfolder
:fn1

for /f %%A In ('Reg Query "HKLM\SOFTWARE\Microsoft\Shared Tools\MSConfig\%1" /v %1^|Find "*"') Do set drt=%%A

echo %drt%
pause

[sov44]

Неужели никто не подскажет, как вывести на экран и удалить содержимое startupreg, startupfolder? :not-me:

[Iska]

sov44:
1) зачем и надо ли выводить на экран?
2) поскольку разрешения у данных подразделов унаследованы, самое простое и надёжное — #4 (http://forum.oszone.net/post-1706177.html#post1706177).

[sov44]

Iska, Интересно понять, как вывести содержимое разделов реестра и выполнить над ними операции. Возможно пригодится для решения других задач.