нужен скрипт для удаления всех файлов кроме нужных для запуска Windows XP

[Dark Ange1]

Суть проблемы: на диске С: находится куча мусорных файлов со случайными названиями и расширениями (более 1,3 млн!). Естественно, проводник будет открывть диск С: вечность. Значит нужен скрипт для удаления с помощью коммандной строки или еще как-нить всех файлов, кроме заданных(в идеале прописать имена файлов и расширения) или нужных для запуска Windows XP (booot.ini, bootfont.bin, ntldr, ntdetct.com, io.sys, msdos.sys и т.д.)
Буду благодарен за любые идеи, может кто проги специальные знает - тож покатит=)

[amel27]

Буду благодарен за любые идеи, может кто проги специальные знает - тож покатит »если способ не важен, зачем было жестко устанавливать категорию (CMD/BAT) ?

нужен скрипт для удаления с помощью коммандной строки или еще как-нить всех файлов, кроме заданных »
@Echo Off

Set ROOT=X:
Set EXCL=SysMask.lst

For /F "Delims=" %%i In ('DIR /B/A:-D/S "%ROOT%\*"^|FindStr /IVRG:"%EXCL%"') Do (
DEL /Q/F "%%i"
)

пример файла SysMask.lst:
\.com$
\.sys$
.:\\boot\.ini$
.:\\bootfont\.bin$
.:\\ntldr$

X: - диск/папка, в которых искать файлы
SysMask.lst - файл, содержащий маски исключения в формате RegExp (FindStr /?)

- не забыть включить в список исключений сам батник и файл списка;
- файлы с атрибутами скрытый/системный игнорируются;
- пустые папки не удаляются;
- проверить работу фильтра перед запуском.

[Bint]

а как бы скорректировать работу этого скрипта для удаления из папок профилей в Documents and Settings всех папок кроме "рабочий стол" и "мои документы" причем скрытые и системные файлы и пустые папки тоже сносить?

[Dark Ange1]

а как скорректировать его так, чтоб только КОРЕНЬ ДИСКА очищался? НО ВСЕ ПАПКИ оставались нетронутыми. А то папка Мои документы ушла в небытие=)

[amel27]

как бы скорректировать работу этого скрипта для удаления из папок профилей в Documents and Settings всех папок кроме "рабочий стол" и "мои документы" причем скрытые и системные файлы и пустые папки тоже сносить »где-то так:
@Echo Off
SetLocal EnableExtensions

Set EXCL=%~dpn0.xcl
PushD X:\Documents and Settings ||Exit

For /F "Delims=" %%i In ('DIR /B/A:D') Do For /F "Delims=" %%j In (
'DIR /B/A:D "%%i"^| FindStr /IVXG:"%EXCL%"^& DIR /B/A:-D "%%i"') Do (
RD /S/Q "%%i\%%j"|| Attrib -S -H "%%i\%%j"&& DEL /F/Q "%%i\%%j") 2>Nul

содержимое одноимённого XCL-файла фильтра (в DOS-кодировке):
Desktop
My Documents
Рабочий стол
Мои документы


чтоб только КОРЕНЬ ДИСКА очищался? НО ВСЕ ПАПКИ оставались нетронутыми »
PushD X:\ ||Exit
For /F "Delims=" %%i In ('DIR /B/A:-D') Do Attrib -H -S "%%i"&& DEL /F/Q "%%i"

[Dark Ange1]

Цитата Dark Ange1:чтоб только КОРЕНЬ ДИСКА очищался? НО ВСЕ ПАПКИ оставались нетронутыми »
Код: PushD X:\ ||Exit For /F "Delims=" %%i In ('DIR /B/A:-D') Do Attrib -H -S "%%i"&& DEL /F/Q "%%i"

А то же самое, но чтобы системные фалы, которые нужны для загрузки (boot.ini, NTLDR, ntdetect.com, io.sys и проч.)

[ziku]

Поставь FAR и удаляй с помощью его что заблагорассудится. Он удаляет ВСЕ!!! даже не удаляемое, не переусердствуй.

[antonhacktm]

Здравствуйте. Извините меня за плохой русский. Я из Болгарии.
У нас есть очень распространенный вирус, который передается через Skype.
Я стараюсь делать сценария для удаления своих файлов. Проблема в том, что каждый компьютер файлы с различными расширениями. До сих пор я собрал более 110.

bqb, bvu, rbs, qiv, wiv, czr, flr, ldv, job, yrk, led, vir, fyf, hpo, oyq, pao, jyl, tuf, ilx, kfa, uro, ayg, dhe, vyl, pyo, vgo, kvx, vah, kvx, uhq, qak, emw, mxk, pxl, odk, xxb, dmy, pai, kee, hox, rjm, oyh, whx, kdd, fwa, qvk, sfr, nfp, kak, afx, lwr, ieo, dov, ebc, ynt, kdt, pvc, vpa, pwl, hpo, brm, bby, jqr, wus, dzt, kwy, ckc, osj, ews, zcy, qju, ihp, fbg, myp, nfj, taq, lvz, ddg, rff, ops, ifa, ytt, bnd, qzo, ssg, xxw, cmu, bqs, mvi, aif, ftv, kvv, cfd, wjq, cku, kvn, axe, xrn, vir, fqr, xze, tgw, uht, zng, ioq, meu, job, oiy, wnf, cdt, nfp, alf, ref, oiu, peq, foa, lyk, kfa

Пожалуйста, помогите

[fomin_]

antonhacktm,
Вам проще составить список расширений файлов, которые нужно оставить, а остальные удалять.
Либо, как вариант, использовать программу аналогичную ShadowUser.
Хотя надо лечить проблему, а не последствия.

[antonhacktm]

Распространения вируса:

%systemdrive%,%SYSTEMROOT%,%SYSTEMROOT%\system32,%windir%\Prefetch

Как легко удалить вирус. Каждый раз с разными расширениями файлов.

[Dark Ange1]

Поставь FAR и удаляй с помощью его что заблагорассудится. Он удаляет ВСЕ!!! даже не удаляемое, не переусердствуй. »
Ага. а ты пробовал натравить Far на папку с буквально 2000000+ мелкими файлами?

[amel27]

antonhacktm,

fomin_ дважды прав, поэтому только из спортивного интереса:

1. На чистой системе формируем список допустимых расширений (файл ExtList.txt):

@Echo Off

Set EXT=ExtList.txt
Set "$X=^^[^^.]*$"
Echo %$X%>"%EXT%"

For /F "Delims=" %%i In (
'DIR /B/A-D "%SystemDrive%" "%SystemRoot%" "%SystemRoot%\System32" "%WinDir%\Prefetch"'
) Do Find /I "%%~xi$" "%EXT%" >Nul||>>"%EXT%" Echo.\%%~xi$

2. На зараженной фильтруем всё лишнее (Echo перед DEL после тестирования удалить):
@Echo Off

Set EXT=ExtList.txt

For %%a In (%SystemDrive% %SystemRoot% %SystemRoot%\System32 %WinDir%\Prefetch) Do (
For /F "Delims=" %%i In ('DIR /B/A-D %%a^|FindStr /VIRG:"%EXT%"') Do Echo DEL /F/Q "%%a\%%i"
)