выделить IP

[FreeOw1]

Приветствую вас, знатоки!

Помогите написать батничек, который выдаст сообщение типа:

наберите в браузере 192.168.1.23:118

где:
192.168.1.23 - будет текущей айпишкой
118 - "мой" порт

если возможно, то проверить присваивается адрес по DHCP, и если это так то вывести текст типа:
IP адрес должен быть постоянным!

Необходимую информацию, может предоставить команда ipconfig. но как выделить только необходимую мне информацию и воспользоваться ею, я не знаю. Посему прошу помощи/совета.

Спасибо!

[amel27]

который выдаст сообщение типа: »
Вариант 1. (служба терминалов должна работать)
For /F "Tokens=2 Delims=={}" %%i In ('WMIC NICCONFIG Where IPEnabled^=TRUE Get IPAddress /Value') Do Set IP=%%~i
Msg 0 "наберите в браузере %IP%:118"

Вариант 2. (служба сообщений должна работать)
For /F "Tokens=2 Delims=={}" %%i In ('WMIC NICCONFIG Where IPEnabled^=TRUE Get IPAddress /Value') Do Set IP=%%~i
Net Send %ComputerName% "наберите в браузере %IP%:118"

Вариант 3. (командная строка)
@Echo Off

For /F "Tokens=2 Delims=:" %%i In ('IPConfig^|Find "IP"') Do Set IP=%%~i
Echo Наберите в браузере%IP%:118
Pause >Nul

[amel27]

проверить присваивается адрес по DHCP, и если это так то вывести текст типа: »

Вариант 1. (служба терминалов должна работать)
For /F "UseBackQ Tokens=2 Delims=={}" %%i In (`WMIC NICCONFIG Where 'IPEnabled^=TRUE And DHCPEnabled^=TRUE' Get DHCPEnabled /Value`) Do Set DHCP=%%~i
If Defined DHCP Msg 0 "IP адрес должен быть постоянным!"
Вариант 2. (служба сообщений должна работать)
For /F "UseBackQ Tokens=2 Delims=={}" %%i In (`WMIC NICCONFIG Where 'IPEnabled^=TRUE And DHCPEnabled^=TRUE' Get DHCPEnabled /Value`) Do Set DHCP=%%~i
If Defined DHCP Net Send %ComputerName% "IP адрес должен быть постоянным!"
Вариант 3. (командная строка)
@Echo Off

For /F "Tokens=2 Delims=:" %%i In ('IPConfig /All^|FindStr /IRC:"DHCP[^:]*: *[0-9][0-9]*\."') Do Set DHCP=%%~i
IF Defined DHCP Echo IP адрес должен быть постоянным!& Pause >Nul

[FreeOwl]

огромнейшее спасибо!

не подскажешь литературку, где об этом подробненько пишут?

@Echo Off
For /F "Tokens=2 Delims=:" %%i In ('IPConfig^|Find "IP"') Do Set IP=%%~i
Echo Наберите в браузере%IP%:118
Pause >Nul »

небольшая корректировка:

Find "IPv4"

а в целом смысл понятен. Ещё раз сенкс

[FreeOw1]

с DHCP не получилось, там в выводе есть:
DUID клиента DHCPv6 . . . . . . . : 00-01-00-01-11-A6-08-BC-00-1D-60-2A-46-E4
и это портит всю "малину"...

[amel27]

не подскажешь литературку, где об этом подробненько пишут? »Полезные ресурсы по скриптовым языкам администрирования (http://forum.oszone.net/thread-130222.html) + HELP + форум
с DHCP не получилось »подправил для IPv4